mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-28 00:24:18 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
44 lines
1.4 KiB
Nix
44 lines
1.4 KiB
Nix
{ lib
|
|
, stdenv
|
|
, edk2
|
|
, llvmPackages
|
|
, util-linux
|
|
, nasm
|
|
, python3
|
|
}:
|
|
edk2.mkDerivation "ShellPkg/ShellPkg.dsc" (finalAttrs: {
|
|
pname = "edk2-uefi-shell";
|
|
inherit (edk2) version;
|
|
|
|
nativeBuildInputs = [ util-linux nasm python3 ]
|
|
++ lib.optionals stdenv.cc.isClang [ llvmPackages.bintools llvmPackages.llvm ];
|
|
strictDeps = true;
|
|
|
|
env.NIX_CFLAGS_COMPILE = toString (lib.optionals stdenv.cc.isClang [ "-fno-pic" "-Qunused-arguments" ]);
|
|
|
|
# Set explicitly to use Python 3 from nixpkgs. Otherwise, the build system will detect and try to
|
|
# use `/usr/bin/python3` on Darwin when sandboxing is disabled.
|
|
PYTHON_COMMAND = "${lib.getBin python3}/bin/python3";
|
|
|
|
# We only have a .efi file in $out which shouldn't be patched or stripped
|
|
dontPatchELF = true;
|
|
dontStrip = true;
|
|
|
|
# GUID hardcoded to match ShellPkg.dsc
|
|
installPhase = ''
|
|
runHook preInstall
|
|
install -D -m0644 Build/Shell/RELEASE*/*/Shell_EA4BB293-2D7F-4456-A681-1F22F42CD0BC.efi $out/shell.efi
|
|
runHook postInstall
|
|
'';
|
|
|
|
passthru.efi = "${finalAttrs.finalPackage}/shell.efi";
|
|
|
|
meta = {
|
|
inherit (edk2.meta) license platforms;
|
|
description = "UEFI Shell from Tianocore EFI development kit";
|
|
homepage = "https://github.com/tianocore/tianocore.github.io/wiki/ShellPkg";
|
|
maintainers = with lib.maintainers; [ LunNova mjoerg ];
|
|
broken = stdenv.hostPlatform.isDarwin && stdenv.hostPlatform.isAarch64;
|
|
};
|
|
})
|