mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-30 19:02:57 +00:00
0b31ada92b
The tests had very much duplication and some if it was even wrong! For
instance, `withRcloneEnv` in the MySQL test didn't have the `"$@"` at
the bottom to execute commands passed to it. Because of that, the MySQL
testcase never checked whether files can be uploaded.
Since tests are just another module-system I decided to abstract away
common things by using it:
* Define a base module with
* an empty `client` node and a `nextcloud` node with defaults
shared among all tests.
* rclone scripts that are used by all tests.
* a `testScript` checking upload/download. Additional checks can be
added via `test-helpers.extraTests`.
* Make common information such as admin user & password shared via
options.
Also, changed the following things:
* The `name` of the final derivation also includes the Nextcloud major
it was tested against.
* Improved the objecstore test by making sure the file was actually
uploaded into the bucket.
61 lines
2.1 KiB
Nix
61 lines
2.1 KiB
Nix
{ name, pkgs, testBase, system, ... }:
|
|
|
|
with import ../../lib/testing-python.nix { inherit system pkgs; };
|
|
runTest ({ config, ... }: {
|
|
inherit name;
|
|
meta = with pkgs.lib.maintainers; {
|
|
maintainers = [ eqyiel ma27 ];
|
|
};
|
|
|
|
imports = [ testBase ];
|
|
|
|
nodes = {
|
|
nextcloud = { config, pkgs, lib, ... }: {
|
|
services.nextcloud = {
|
|
caching = {
|
|
apcu = false;
|
|
redis = true;
|
|
memcached = false;
|
|
};
|
|
config.dbtype = "pgsql";
|
|
notify_push = {
|
|
enable = true;
|
|
logLevel = "debug";
|
|
};
|
|
extraAppsEnable = true;
|
|
extraApps = with config.services.nextcloud.package.packages.apps; {
|
|
inherit notify_push notes;
|
|
};
|
|
settings.trusted_proxies = [ "::1" ];
|
|
};
|
|
|
|
services.redis.servers."nextcloud".enable = true;
|
|
services.redis.servers."nextcloud".port = 6379;
|
|
};
|
|
};
|
|
|
|
test-helpers.init = let
|
|
configureRedis = pkgs.writeScript "configure-redis" ''
|
|
nextcloud-occ config:system:set redis 'host' --value 'localhost' --type string
|
|
nextcloud-occ config:system:set redis 'port' --value 6379 --type integer
|
|
nextcloud-occ config:system:set memcache.local --value '\OC\Memcache\Redis' --type string
|
|
nextcloud-occ config:system:set memcache.locking --value '\OC\Memcache\Redis' --type string
|
|
'';
|
|
in ''
|
|
nextcloud.succeed("${configureRedis}")
|
|
'';
|
|
|
|
test-helpers.extraTests = ''
|
|
with subtest("notify-push"):
|
|
client.execute("${pkgs.lib.getExe pkgs.nextcloud-notify_push.passthru.test_client} http://nextcloud ${config.adminuser} ${config.adminpass} >&2 &")
|
|
nextcloud.wait_until_succeeds("journalctl -u nextcloud-notify_push | grep -q \"Sending ping to ${config.adminuser}\"")
|
|
|
|
with subtest("Redis is used for caching"):
|
|
# redis cache should not be empty
|
|
nextcloud.fail('test "[]" = "$(redis-cli --json KEYS "*")"')
|
|
|
|
with subtest("No code is returned when requesting PHP files (regression test)"):
|
|
nextcloud.fail("curl -f http://nextcloud/nix-apps/notes/lib/AppInfo/Application.php")
|
|
'';
|
|
})
|