mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-01 18:44:07 +00:00
4f0dadbf38
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build a08b3a4d19.tar.gz \
--argstr baseRev b32a094368
result/bin/apply-formatting $NIXPKGS_PATH
85 lines
2.4 KiB
Nix
85 lines
2.4 KiB
Nix
# Not everyone has a suitable remote builder set up, so the cross-compilation
|
|
# tests that _include_ running the result are separate. That way, most people
|
|
# can run the majority of the test suite without the extra setup.
|
|
|
|
import ./make-test-python.nix (
|
|
{ pkgs, ... }:
|
|
let
|
|
|
|
remoteSystem =
|
|
if pkgs.stdenv.hostPlatform.system == "aarch64-linux" then "x86_64-linux" else "aarch64-linux";
|
|
|
|
remoteCrossPkgs =
|
|
import ../.. # nixpkgs
|
|
{
|
|
# NOTE: This is the machine that runs the build - local from the
|
|
# 'perspective' of the build script.
|
|
localSystem = remoteSystem;
|
|
|
|
# NOTE: Since this file can't control where the test will be _run_ we don't
|
|
# cross-compile _to_ a different system but _from_ a different system
|
|
crossSystem = pkgs.stdenv.hostPlatform.system;
|
|
};
|
|
|
|
hello1 = remoteCrossPkgs.dockerTools.buildImage {
|
|
name = "hello1";
|
|
tag = "latest";
|
|
copyToRoot = remoteCrossPkgs.buildEnv {
|
|
name = "image-root";
|
|
pathsToLink = [ "/bin" ];
|
|
paths = [ remoteCrossPkgs.hello ];
|
|
};
|
|
};
|
|
|
|
hello2 = remoteCrossPkgs.dockerTools.buildLayeredImage {
|
|
name = "hello2";
|
|
tag = "latest";
|
|
contents = remoteCrossPkgs.hello;
|
|
};
|
|
|
|
in
|
|
{
|
|
name = "docker-tools";
|
|
meta = with pkgs.lib.maintainers; {
|
|
maintainers = [ roberth ];
|
|
};
|
|
|
|
nodes = {
|
|
docker =
|
|
{ ... }:
|
|
{
|
|
virtualisation = {
|
|
diskSize = 2048;
|
|
docker.enable = true;
|
|
};
|
|
};
|
|
};
|
|
|
|
testScript = ''
|
|
docker.wait_for_unit("sockets.target")
|
|
|
|
with subtest("Ensure cross compiled buildImage image can run."):
|
|
docker.succeed(
|
|
"docker load --input='${hello1}'"
|
|
)
|
|
assert "Hello, world!" in docker.succeed(
|
|
"docker run --rm ${hello1.imageName} hello",
|
|
)
|
|
docker.succeed(
|
|
"docker rmi ${hello1.imageName}",
|
|
)
|
|
|
|
with subtest("Ensure cross compiled buildLayeredImage image can run."):
|
|
docker.succeed(
|
|
"docker load --input='${hello2}'"
|
|
)
|
|
assert "Hello, world!" in docker.succeed(
|
|
"docker run --rm ${hello2.imageName} hello",
|
|
)
|
|
docker.succeed(
|
|
"docker rmi ${hello2.imageName}",
|
|
)
|
|
'';
|
|
}
|
|
)
|