mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-28 00:24:18 +00:00
4f0dadbf38
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build a08b3a4d19.tar.gz \
--argstr baseRev b32a094368
result/bin/apply-formatting $NIXPKGS_PATH
75 lines
1.7 KiB
Nix
75 lines
1.7 KiB
Nix
/*
|
|
# New packages
|
|
|
|
READ THIS FIRST
|
|
|
|
This module is for official packages in the Plasma Mobile Gear. All
|
|
available packages are listed in `./srcs.nix`, although some are not yet
|
|
packaged in Nixpkgs.
|
|
|
|
IF YOUR PACKAGE IS NOT LISTED IN `./srcs.nix`, IT DOES NOT GO HERE.
|
|
|
|
See also `pkgs/applications/kde` as this is what this is based on.
|
|
|
|
# Updates
|
|
|
|
1. Update the URL in `./fetch.sh`.
|
|
2. Run `./maintainers/scripts/fetch-kde-qt.sh pkgs/applications/plasma-mobile`
|
|
from the top of the Nixpkgs tree.
|
|
3. Use `nox-review wip` to check that everything builds.
|
|
4. Commit the changes and open a pull request.
|
|
*/
|
|
|
|
{
|
|
lib,
|
|
libsForQt5,
|
|
fetchurl,
|
|
}:
|
|
|
|
let
|
|
mirror = "mirror://kde";
|
|
srcs = import ./srcs.nix { inherit fetchurl mirror; };
|
|
|
|
mkDerivation =
|
|
args:
|
|
let
|
|
inherit (args) pname;
|
|
inherit (srcs.${pname}) src version;
|
|
mkDerivation = libsForQt5.callPackage ({ mkDerivation }: mkDerivation) { };
|
|
in
|
|
mkDerivation (
|
|
args
|
|
// {
|
|
inherit pname version src;
|
|
|
|
outputs = args.outputs or [ "out" ];
|
|
|
|
meta =
|
|
let
|
|
meta = args.meta or { };
|
|
in
|
|
meta
|
|
// {
|
|
homepage = meta.homepage or "https://www.plasma-mobile.org/";
|
|
platforms = meta.platforms or lib.platforms.linux;
|
|
};
|
|
}
|
|
);
|
|
|
|
packages =
|
|
self:
|
|
let
|
|
callPackage = self.newScope {
|
|
inherit mkDerivation;
|
|
};
|
|
in
|
|
{
|
|
plasma-dialer = callPackage ./plasma-dialer.nix { };
|
|
plasma-phonebook = callPackage ./plasma-phonebook.nix { };
|
|
plasma-settings = callPackage ./plasma-settings.nix { };
|
|
spacebar = callPackage ./spacebar.nix { };
|
|
};
|
|
|
|
in
|
|
lib.makeScope libsForQt5.newScope packages
|