mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-15 10:12:58 +00:00
2e751c0772
the conversion procedure is simple: - find all things that look like options, ie calls to either `mkOption` or `lib.mkOption` that take an attrset. remember the attrset as the option - for all options, find a `description` attribute who's value is not a call to `mdDoc` or `lib.mdDoc` - textually convert the entire value of the attribute to MD with a few simple regexes (the set from mdize-module.sh) - if the change produced a change in the manual output, discard - if the change kept the manual unchanged, add some text to the description to make sure we've actually found an option. if the manual changes this time, keep the converted description this procedure converts 80% of nixos options to markdown. around 2000 options remain to be inspected, but most of those fail the "does not change the manual output check": currently the MD conversion process does not faithfully convert docbook tags like <code> and <package>, so any option using such tags will not be converted at all.
72 lines
1.8 KiB
Nix
72 lines
1.8 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
let
|
|
inherit (lib)
|
|
mkEnableOption mkIf mkOption types
|
|
recursiveUpdate;
|
|
|
|
cfg = config.networking.wireless.iwd;
|
|
ini = pkgs.formats.ini { };
|
|
defaults = {
|
|
# without UseDefaultInterface, sometimes wlan0 simply goes AWOL with NetworkManager
|
|
# https://iwd.wiki.kernel.org/interface_lifecycle#interface_management_in_iwd
|
|
General.UseDefaultInterface = with config.networking.networkmanager; (enable && (wifi.backend == "iwd"));
|
|
};
|
|
configFile = ini.generate "main.conf" (recursiveUpdate defaults cfg.settings);
|
|
|
|
in
|
|
{
|
|
options.networking.wireless.iwd = {
|
|
enable = mkEnableOption "iwd";
|
|
|
|
settings = mkOption {
|
|
type = ini.type;
|
|
default = { };
|
|
|
|
example = {
|
|
Settings.AutoConnect = true;
|
|
|
|
Network = {
|
|
EnableIPv6 = true;
|
|
RoutePriorityOffset = 300;
|
|
};
|
|
};
|
|
|
|
description = lib.mdDoc ''
|
|
Options passed to iwd.
|
|
See [here](https://iwd.wiki.kernel.org/networkconfigurationsettings) for supported options.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
assertions = [{
|
|
assertion = !config.networking.wireless.enable;
|
|
message = ''
|
|
Only one wireless daemon is allowed at the time: networking.wireless.enable and networking.wireless.iwd.enable are mutually exclusive.
|
|
'';
|
|
}];
|
|
|
|
environment.etc."iwd/${configFile.name}".source = configFile;
|
|
|
|
# for iwctl
|
|
environment.systemPackages = [ pkgs.iwd ];
|
|
|
|
services.dbus.packages = [ pkgs.iwd ];
|
|
|
|
systemd.packages = [ pkgs.iwd ];
|
|
|
|
systemd.network.links."80-iwd" = {
|
|
matchConfig.Type = "wlan";
|
|
linkConfig.NamePolicy = "keep kernel";
|
|
};
|
|
|
|
systemd.services.iwd = {
|
|
wantedBy = [ "multi-user.target" ];
|
|
restartTriggers = [ configFile ];
|
|
};
|
|
};
|
|
|
|
meta.maintainers = with lib.maintainers; [ mic92 dtzWill ];
|
|
}
|