mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-15 02:03:01 +00:00
2e751c0772
the conversion procedure is simple: - find all things that look like options, ie calls to either `mkOption` or `lib.mkOption` that take an attrset. remember the attrset as the option - for all options, find a `description` attribute who's value is not a call to `mdDoc` or `lib.mdDoc` - textually convert the entire value of the attribute to MD with a few simple regexes (the set from mdize-module.sh) - if the change produced a change in the manual output, discard - if the change kept the manual unchanged, add some text to the description to make sure we've actually found an option. if the manual changes this time, keep the converted description this procedure converts 80% of nixos options to markdown. around 2000 options remain to be inspected, but most of those fail the "does not change the manual output check": currently the MD conversion process does not faithfully convert docbook tags like <code> and <package>, so any option using such tags will not be converted at all.
87 lines
1.9 KiB
Nix
87 lines
1.9 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
cfg = config.services.freeradius;
|
|
|
|
freeradiusService = cfg:
|
|
{
|
|
description = "FreeRadius server";
|
|
wantedBy = ["multi-user.target"];
|
|
after = ["network.target"];
|
|
wants = ["network.target"];
|
|
preStart = ''
|
|
${pkgs.freeradius}/bin/radiusd -C -d ${cfg.configDir} -l stdout
|
|
'';
|
|
|
|
serviceConfig = {
|
|
ExecStart = "${pkgs.freeradius}/bin/radiusd -f -d ${cfg.configDir} -l stdout" +
|
|
optionalString cfg.debug " -xx";
|
|
ExecReload = [
|
|
"${pkgs.freeradius}/bin/radiusd -C -d ${cfg.configDir} -l stdout"
|
|
"${pkgs.coreutils}/bin/kill -HUP $MAINPID"
|
|
];
|
|
User = "radius";
|
|
ProtectSystem = "full";
|
|
ProtectHome = "on";
|
|
Restart = "on-failure";
|
|
RestartSec = 2;
|
|
LogsDirectory = "radius";
|
|
};
|
|
};
|
|
|
|
freeradiusConfig = {
|
|
enable = mkEnableOption "the freeradius server";
|
|
|
|
configDir = mkOption {
|
|
type = types.path;
|
|
default = "/etc/raddb";
|
|
description = lib.mdDoc ''
|
|
The path of the freeradius server configuration directory.
|
|
'';
|
|
};
|
|
|
|
debug = mkOption {
|
|
type = types.bool;
|
|
default = false;
|
|
description = lib.mdDoc ''
|
|
Whether to enable debug logging for freeradius (-xx
|
|
option). This should not be left on, since it includes
|
|
sensitive data such as passwords in the logs.
|
|
'';
|
|
};
|
|
|
|
};
|
|
|
|
in
|
|
|
|
{
|
|
|
|
###### interface
|
|
|
|
options = {
|
|
services.freeradius = freeradiusConfig;
|
|
};
|
|
|
|
|
|
###### implementation
|
|
|
|
config = mkIf (cfg.enable) {
|
|
|
|
users = {
|
|
users.radius = {
|
|
/*uid = config.ids.uids.radius;*/
|
|
description = "Radius daemon user";
|
|
isSystemUser = true;
|
|
};
|
|
};
|
|
|
|
systemd.services.freeradius = freeradiusService cfg;
|
|
warnings = optional cfg.debug "Freeradius debug logging is enabled. This will log passwords in plaintext to the journal!";
|
|
|
|
};
|
|
|
|
}
|