mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-01 07:01:54 +00:00
f05d8f31ec
cleanSource does not appear to work correctly in this case. The path does not get coerced to a string, resulting in a dangling symlink produced in channel.nix. Not sure why, but this seems to fix it. Fixes #51025. /cc @elvishjericco
48 lines
1.6 KiB
Nix
48 lines
1.6 KiB
Nix
# Provide an initial copy of the NixOS channel so that the user
|
|
# doesn't need to run "nix-channel --update" first.
|
|
|
|
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
nixpkgs = lib.cleanSource pkgs.path;
|
|
|
|
# We need a copy of the Nix expressions for Nixpkgs and NixOS on the
|
|
# CD. These are installed into the "nixos" channel of the root
|
|
# user, as expected by nixos-rebuild/nixos-install. FIXME: merge
|
|
# with make-channel.nix.
|
|
channelSources = pkgs.runCommand "nixos-${config.system.nixos.version}"
|
|
{ }
|
|
''
|
|
mkdir -p $out
|
|
cp -prd ${nixpkgs.outPath} $out/nixos
|
|
chmod -R u+w $out/nixos
|
|
if [ ! -e $out/nixos/nixpkgs ]; then
|
|
ln -s . $out/nixos/nixpkgs
|
|
fi
|
|
echo -n ${config.system.nixos.revision} > $out/nixos/.git-revision
|
|
echo -n ${config.system.nixos.versionSuffix} > $out/nixos/.version-suffix
|
|
echo ${config.system.nixos.versionSuffix} | sed -e s/pre// > $out/nixos/svn-revision
|
|
'';
|
|
|
|
in
|
|
|
|
{
|
|
# Provide the NixOS/Nixpkgs sources in /etc/nixos. This is required
|
|
# for nixos-install.
|
|
boot.postBootCommands = mkAfter
|
|
''
|
|
if ! [ -e /var/lib/nixos/did-channel-init ]; then
|
|
echo "unpacking the NixOS/Nixpkgs sources..."
|
|
mkdir -p /nix/var/nix/profiles/per-user/root
|
|
${config.nix.package.out}/bin/nix-env -p /nix/var/nix/profiles/per-user/root/channels \
|
|
-i ${channelSources} --quiet --option build-use-substitutes false
|
|
mkdir -m 0700 -p /root/.nix-defexpr
|
|
ln -s /nix/var/nix/profiles/per-user/root/channels /root/.nix-defexpr/channels
|
|
mkdir -m 0755 -p /var/lib/nixos
|
|
touch /var/lib/nixos/did-channel-init
|
|
fi
|
|
'';
|
|
}
|