mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-28 16:43:58 +00:00
4f0dadbf38
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build a08b3a4d19.tar.gz \
--argstr baseRev b32a094368
result/bin/apply-formatting $NIXPKGS_PATH
106 lines
2.1 KiB
Nix
106 lines
2.1 KiB
Nix
# This expression returns a list of all fetchurl calls used by ‘expr’.
|
||
|
||
{
|
||
expr,
|
||
lib ? import ../../lib,
|
||
}:
|
||
|
||
let
|
||
inherit (lib)
|
||
addErrorContext
|
||
attrNames
|
||
concatLists
|
||
const
|
||
filter
|
||
genericClosure
|
||
isAttrs
|
||
isDerivation
|
||
isList
|
||
mapAttrsToList
|
||
optional
|
||
optionals
|
||
;
|
||
|
||
root = expr;
|
||
|
||
uniqueFiles = map (x: x.file) (genericClosure {
|
||
startSet = map (file: {
|
||
key = with file; (if type == null then "" else type + "+") + hash;
|
||
inherit file;
|
||
}) files;
|
||
operator = const [ ];
|
||
});
|
||
|
||
files = map (drv: {
|
||
urls = drv.urls or [ drv.url ];
|
||
hash = drv.outputHash;
|
||
isPatch = (drv ? postFetch && drv.postFetch != "");
|
||
type = drv.outputHashAlgo;
|
||
name = drv.name;
|
||
}) fetchurlDependencies;
|
||
|
||
fetchurlDependencies = filter (
|
||
drv:
|
||
drv.outputHash or "" != "" && drv.outputHashMode or "flat" == "flat" && (drv ? url || drv ? urls)
|
||
) dependencies;
|
||
|
||
dependencies = map (x: x.value) (genericClosure {
|
||
startSet = map keyDrv (derivationsIn' root);
|
||
operator = { key, value }: map keyDrv (immediateDependenciesOf value);
|
||
});
|
||
|
||
derivationsIn' =
|
||
x:
|
||
if !canEval x then
|
||
[ ]
|
||
else if isDerivation x then
|
||
optional (canEval x.drvPath) x
|
||
else if isList x then
|
||
concatLists (map derivationsIn' x)
|
||
else if isAttrs x then
|
||
concatLists (
|
||
mapAttrsToList (n: v: addErrorContext "while finding tarballs in '${n}':" (derivationsIn' v)) x
|
||
)
|
||
else
|
||
[ ];
|
||
|
||
keyDrv =
|
||
drv:
|
||
if canEval drv.drvPath then
|
||
{
|
||
key = drv.drvPath;
|
||
value = drv;
|
||
}
|
||
else
|
||
{ };
|
||
|
||
immediateDependenciesOf =
|
||
drv:
|
||
concatLists (
|
||
mapAttrsToList (n: v: derivationsIn v) (
|
||
removeAttrs drv (
|
||
[
|
||
"meta"
|
||
"passthru"
|
||
]
|
||
++ optionals (drv ? passthru) (attrNames drv.passthru)
|
||
)
|
||
)
|
||
);
|
||
|
||
derivationsIn =
|
||
x:
|
||
if !canEval x then
|
||
[ ]
|
||
else if isDerivation x then
|
||
optional (canEval x.drvPath) x
|
||
else if isList x then
|
||
concatLists (map derivationsIn x)
|
||
else
|
||
[ ];
|
||
|
||
canEval = val: (builtins.tryEval val).success;
|
||
|
||
in
|
||
uniqueFiles
|