mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-24 22:04:20 +00:00
e0464e4788
In preparation for the deprecation of `stdenv.isX`. These shorthands are not conducive to cross-compilation because they hide the platforms. Darwin might get cross-compilation for which the continued usage of `stdenv.isDarwin` will get in the way One example of why this is bad and especially affects compiler packages https://www.github.com/NixOS/nixpkgs/pull/343059 There are too many files to go through manually but a treewide should get users thinking when they see a `hostPlatform.isX` in a place where it doesn't make sense. ``` fd --type f "\.nix" | xargs sd --fixed-strings "stdenv.is" "stdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenv'.is" "stdenv'.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "clangStdenv.is" "clangStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "gccStdenv.is" "gccStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenvNoCC.is" "stdenvNoCC.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "inherit (stdenv) is" "inherit (stdenv.hostPlatform) is" fd --type f "\.nix" | xargs sd --fixed-strings "buildStdenv.is" "buildStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "effectiveStdenv.is" "effectiveStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "originalStdenv.is" "originalStdenv.hostPlatform.is" ```
121 lines
3.6 KiB
Nix
121 lines
3.6 KiB
Nix
{ pkgsBuildBuild
|
|
, go
|
|
, buildGoModule
|
|
, stdenv
|
|
, lib
|
|
, procps
|
|
, fetchFromGitHub
|
|
, nixosTests
|
|
, autoSignDarwinBinariesHook
|
|
}:
|
|
|
|
let
|
|
common = { stname, target, postInstall ? "" }:
|
|
buildGoModule rec {
|
|
pname = stname;
|
|
version = "1.27.12";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "syncthing";
|
|
repo = "syncthing";
|
|
rev = "v${version}";
|
|
hash = "sha256-/HPq71KkWUE0vG7qUBD3JON4N5KBkuRWc4SvX/JA2nQ=";
|
|
};
|
|
|
|
vendorHash = "sha256-R5GlsCkfoMc5km+NaV+TNUlM3Ot1ARcXfEFimcZOLI4=";
|
|
|
|
nativeBuildInputs = lib.optionals stdenv.hostPlatform.isDarwin [
|
|
# Recent versions of macOS seem to require binaries to be signed when
|
|
# run from Launch Agents/Daemons, even on x86 devices where it has a
|
|
# more lax code signing policy compared to Apple Silicon. So just sign
|
|
# the binaries on both architectures to make it possible for launchd to
|
|
# auto-start Syncthing at login.
|
|
autoSignDarwinBinariesHook
|
|
];
|
|
|
|
doCheck = false;
|
|
|
|
BUILD_USER = "nix";
|
|
BUILD_HOST = "nix";
|
|
|
|
buildPhase = ''
|
|
runHook preBuild
|
|
(
|
|
export GOOS="${pkgsBuildBuild.go.GOOS}" GOARCH="${pkgsBuildBuild.go.GOARCH}" CC=$CC_FOR_BUILD
|
|
go build build.go
|
|
go generate github.com/syncthing/syncthing/lib/api/auto github.com/syncthing/syncthing/cmd/strelaypoolsrv/auto
|
|
)
|
|
./build -goos ${go.GOOS} -goarch ${go.GOARCH} -no-upgrade -version v${version} build ${target}
|
|
runHook postBuild
|
|
'';
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
install -Dm755 ${target} $out/bin/${target}
|
|
runHook postInstall
|
|
'';
|
|
|
|
inherit postInstall;
|
|
|
|
passthru.tests = {
|
|
inherit (nixosTests) syncthing syncthing-init syncthing-relay;
|
|
};
|
|
|
|
meta = {
|
|
homepage = "https://syncthing.net/";
|
|
description = "Open Source Continuous File Synchronization";
|
|
changelog = "https://github.com/syncthing/syncthing/releases/tag/v${version}";
|
|
license = lib.licenses.mpl20;
|
|
maintainers = with lib.maintainers; [ joko peterhoeg ];
|
|
mainProgram = target;
|
|
platforms = lib.platforms.unix;
|
|
};
|
|
};
|
|
|
|
in
|
|
{
|
|
syncthing = common {
|
|
stname = "syncthing";
|
|
target = "syncthing";
|
|
|
|
postInstall = ''
|
|
# This installs man pages in the correct directory according to the suffix
|
|
# on the filename
|
|
for mf in man/*.[1-9]; do
|
|
mantype="$(echo "$mf" | awk -F"." '{print $NF}')"
|
|
mandir="$out/share/man/man$mantype"
|
|
install -Dm644 "$mf" "$mandir/$(basename "$mf")"
|
|
done
|
|
|
|
'' + lib.optionalString (stdenv.hostPlatform.isLinux) ''
|
|
mkdir -p $out/lib/systemd/{system,user}
|
|
|
|
substitute etc/linux-systemd/system/syncthing@.service \
|
|
$out/lib/systemd/system/syncthing@.service \
|
|
--replace-fail /usr/bin/syncthing $out/bin/syncthing
|
|
|
|
substitute etc/linux-systemd/user/syncthing.service \
|
|
$out/lib/systemd/user/syncthing.service \
|
|
--replace-fail /usr/bin/syncthing $out/bin/syncthing
|
|
'';
|
|
};
|
|
|
|
syncthing-discovery = common {
|
|
stname = "syncthing-discovery";
|
|
target = "stdiscosrv";
|
|
};
|
|
|
|
syncthing-relay = common {
|
|
stname = "syncthing-relay";
|
|
target = "strelaysrv";
|
|
|
|
postInstall = lib.optionalString (stdenv.hostPlatform.isLinux) ''
|
|
mkdir -p $out/lib/systemd/system
|
|
|
|
substitute cmd/strelaysrv/etc/linux-systemd/strelaysrv.service \
|
|
$out/lib/systemd/system/strelaysrv.service \
|
|
--replace-fail /usr/bin/strelaysrv $out/bin/strelaysrv
|
|
'';
|
|
};
|
|
}
|