mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-29 09:04:17 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
99 lines
2.3 KiB
Nix
99 lines
2.3 KiB
Nix
{ lib
|
|
, rustPlatform
|
|
, fetchFromGitLab
|
|
, systemd
|
|
, coreutils
|
|
, gnugrep
|
|
, pkg-config
|
|
, fontconfig
|
|
, libGL
|
|
, libinput
|
|
, libxkbcommon
|
|
, mesa
|
|
, seatd
|
|
, wayland
|
|
}:
|
|
|
|
rustPlatform.buildRustPackage rec {
|
|
pname = "asusctl";
|
|
version = "6.0.12";
|
|
|
|
src = fetchFromGitLab {
|
|
owner = "asus-linux";
|
|
repo = "asusctl";
|
|
rev = version;
|
|
hash = "sha256-fod3ZkJktmJGHF8nSSp9lVMg/qYKQd4EiauFGTSvbsg=";
|
|
};
|
|
|
|
cargoLock = {
|
|
lockFile = ./Cargo.lock;
|
|
outputHashes = {
|
|
"const-field-offset-0.1.5" = "sha256-QtlvLwe27tLLdWhqiKzXoUvBsBcZbfwY84jXUduzCKw=";
|
|
"supergfxctl-5.2.4" = "sha256-MQJJaTajPQ45BU6zyMx0Wwf7tAPcT4EURWWbZxrbGzE=";
|
|
};
|
|
};
|
|
|
|
postPatch = ''
|
|
files="
|
|
asusd-user/src/config.rs
|
|
asusd-user/src/daemon.rs
|
|
asusd/src/ctrl_anime/config.rs
|
|
rog-aura/src/aura_detection.rs
|
|
rog-control-center/src/lib.rs
|
|
rog-control-center/src/main.rs
|
|
rog-control-center/src/tray.rs
|
|
"
|
|
for file in $files; do
|
|
substituteInPlace $file --replace /usr/share $out/share
|
|
done
|
|
|
|
substituteInPlace data/asusd.rules --replace systemctl ${systemd}/bin/systemctl
|
|
substituteInPlace data/asusd.service \
|
|
--replace /usr/bin/asusd $out/bin/asusd \
|
|
--replace /bin/sleep ${coreutils}/bin/sleep
|
|
substituteInPlace data/asusd-user.service \
|
|
--replace /usr/bin/asusd-user $out/bin/asusd-user \
|
|
--replace /usr/bin/sleep ${coreutils}/bin/sleep
|
|
|
|
substituteInPlace Makefile \
|
|
--replace /usr/bin/grep ${lib.getExe gnugrep}
|
|
'';
|
|
|
|
nativeBuildInputs = [ pkg-config ];
|
|
|
|
buildInputs = [
|
|
fontconfig
|
|
libGL
|
|
libinput
|
|
libxkbcommon
|
|
mesa
|
|
seatd
|
|
systemd
|
|
wayland
|
|
];
|
|
|
|
# force linking to all the dlopen()ed dependencies
|
|
RUSTFLAGS = map (a: "-C link-arg=${a}") [
|
|
"-Wl,--push-state,--no-as-needed"
|
|
"-lEGL"
|
|
"-lfontconfig"
|
|
"-lwayland-client"
|
|
"-Wl,--pop-state"
|
|
];
|
|
|
|
# upstream has minimal tests, so don't rebuild twice
|
|
doCheck = false;
|
|
|
|
postInstall = ''
|
|
make prefix=$out install-data
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Control daemon, CLI tools, and a collection of crates for interacting with ASUS ROG laptops";
|
|
homepage = "https://gitlab.com/asus-linux/asusctl";
|
|
license = licenses.mpl20;
|
|
platforms = [ "x86_64-linux" ];
|
|
maintainers = with maintainers; [ k900 aacebedo ];
|
|
};
|
|
}
|