mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-07 13:33:12 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
88 lines
1.9 KiB
Nix
88 lines
1.9 KiB
Nix
{ copyDesktopItems
|
|
, fetchurl
|
|
, glib
|
|
, adwaita-icon-theme
|
|
, gtk3
|
|
, jre
|
|
, lib
|
|
, makeDesktopItem
|
|
, stdenv
|
|
, wrapGAppsHook3
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "deepgit";
|
|
version = "4.4";
|
|
|
|
src = fetchurl {
|
|
url = "https://www.syntevo.com/downloads/deepgit/deepgit-linux-${lib.replaceStrings [ "." ] [ "_" ] version}.tar.gz";
|
|
hash = "sha256-ILqwXDyW7/hZzoSxxaxv4bF5xsB/JFaOBYAJFb7xmdk=";
|
|
};
|
|
|
|
nativeBuildInputs = [
|
|
copyDesktopItems
|
|
wrapGAppsHook3
|
|
];
|
|
|
|
buildInputs = [
|
|
adwaita-icon-theme
|
|
gtk3
|
|
jre
|
|
];
|
|
|
|
preFixup = ''
|
|
gappsWrapperArgs+=(
|
|
--prefix LD_LIBRARY_PATH : ${lib.makeLibraryPath [ glib gtk3 ]}
|
|
--set DEEPGIT_JAVA_HOME ${jre}
|
|
)
|
|
patchShebangs bin/deepgit.sh
|
|
'';
|
|
|
|
desktopItems = [(makeDesktopItem rec {
|
|
name = pname;
|
|
desktopName = "DeepGit";
|
|
keywords = [ "git" ];
|
|
comment = "Git-Client";
|
|
categories = [
|
|
"Development"
|
|
"RevisionControl"
|
|
];
|
|
terminal = false;
|
|
startupNotify = true;
|
|
startupWMClass = desktopName;
|
|
exec = pname;
|
|
mimeTypes = [
|
|
"x-scheme-handler/${pname}"
|
|
"x-scheme-handler/sourcetree"
|
|
];
|
|
icon = pname;
|
|
})];
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
|
|
mkdir -pv $out/{bin,share/icons/hicolor/scalable/apps/}
|
|
cp -a lib license.html $out
|
|
mv bin/deepgit.sh $out/bin/deepgit
|
|
|
|
for icon_size in 32 48 64 128 256; do
|
|
path=$icon_size'x'$icon_size
|
|
icon=bin/deepgit-$icon_size.png
|
|
mkdir -p $out/share/icons/hicolor/$path/apps
|
|
cp $icon $out/share/icons/hicolor/$path/apps/deepgit.png
|
|
done
|
|
|
|
runHook postInstall
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Tool to investigate the history of source code";
|
|
homepage = "https://www.syntevo.com/deepgit";
|
|
changelog = "https://www.syntevo.com/deepgit/changelog.txt";
|
|
license = licenses.unfree;
|
|
maintainers = with maintainers; [ urandom ];
|
|
platforms = platforms.linux;
|
|
mainProgram = "deepgit";
|
|
};
|
|
}
|