mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-28 00:24:18 +00:00
4f0dadbf38
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build a08b3a4d19.tar.gz \
--argstr baseRev b32a094368
result/bin/apply-formatting $NIXPKGS_PATH
62 lines
1.5 KiB
Nix
62 lines
1.5 KiB
Nix
{ config, lib, ... }:
|
|
{
|
|
meta = {
|
|
maintainers = [ lib.maintainers.joachifm ];
|
|
};
|
|
|
|
options = {
|
|
security.lockKernelModules = lib.mkOption {
|
|
type = lib.types.bool;
|
|
default = false;
|
|
description = ''
|
|
Disable kernel module loading once the system is fully initialised.
|
|
Module loading is disabled until the next reboot. Problems caused
|
|
by delayed module loading can be fixed by adding the module(s) in
|
|
question to {option}`boot.kernelModules`.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = lib.mkIf config.security.lockKernelModules {
|
|
boot.kernelModules = lib.concatMap (
|
|
x:
|
|
lib.optionals (x.device != null) (
|
|
if x.fsType == "vfat" then
|
|
[
|
|
"vfat"
|
|
"nls-cp437"
|
|
"nls-iso8859-1"
|
|
]
|
|
else
|
|
[ x.fsType ]
|
|
)
|
|
) config.system.build.fileSystems;
|
|
|
|
systemd.services.disable-kernel-module-loading = {
|
|
description = "Disable kernel module loading";
|
|
|
|
wants = [ "systemd-udevd.service" ];
|
|
wantedBy = [ config.systemd.defaultUnit ];
|
|
|
|
after = [
|
|
"firewall.service"
|
|
"systemd-modules-load.service"
|
|
config.systemd.defaultUnit
|
|
];
|
|
|
|
unitConfig.ConditionPathIsReadWrite = "/proc/sys/kernel";
|
|
|
|
serviceConfig = {
|
|
Type = "oneshot";
|
|
RemainAfterExit = true;
|
|
TimeoutSec = 180;
|
|
};
|
|
|
|
script = ''
|
|
${config.systemd.package}/bin/udevadm settle
|
|
echo -n 1 >/proc/sys/kernel/modules_disabled
|
|
'';
|
|
};
|
|
};
|
|
}
|