mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-09 14:33:22 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
101 lines
3.5 KiB
Nix
101 lines
3.5 KiB
Nix
{
|
|
lib,
|
|
rustPlatform,
|
|
fetchFromGitHub,
|
|
pkg-config,
|
|
sqlite,
|
|
zstd,
|
|
fetchurl,
|
|
}:
|
|
|
|
let
|
|
apexcharts = fetchurl {
|
|
url = "https://cdn.jsdelivr.net/npm/apexcharts@3.52.0/dist/apexcharts.min.js";
|
|
hash = "sha256-2sxp9+shRA5LMxzhgx+fpeQPIY2ZWgBdt4mp5V2Yn+E=";
|
|
};
|
|
tablerCss = fetchurl {
|
|
url = "https://cdn.jsdelivr.net/npm/@tabler/core@1.0.0-beta20/dist/css/tabler.min.css";
|
|
hash = "sha256-lS3nKxMMZiKIRJG7UgUonOHYuvHgW5eckEjvHMYxb9Q=";
|
|
};
|
|
tablerVendorsCss = fetchurl {
|
|
url = "https://cdn.jsdelivr.net/npm/@tabler/core@1.0.0-beta20/dist/css/tabler-vendors.min.css";
|
|
hash = "sha256-Aa7AUOaz6hJLiUzQStZTy2VPOZyg0ViSo2MCzpDU1tY=";
|
|
};
|
|
tablerJs = fetchurl {
|
|
url = "https://cdn.jsdelivr.net/npm/@tabler/core@1.0.0-beta20/dist/js/tabler.min.js";
|
|
hash = "sha256-ygO5OTRUtYxDDkERRwBCfq+fmakhM6ybwfl6gCCPlAQ=";
|
|
};
|
|
listJsFixed = fetchurl {
|
|
url = "https://cdn.jsdelivr.net/npm/list.js-fixed@2.3.4/dist/list.min.js";
|
|
hash = "sha256-sYy7qNJW7RTuaNA0jq6Yrtfs57ypYrItZ3f8T7kqfPM=";
|
|
};
|
|
tablerIcons = fetchurl {
|
|
url = "https://cdn.jsdelivr.net/npm/@tabler/icons-sprite@3.10.0/dist/tabler-sprite.svg";
|
|
hash = "sha256-lEUAtxI+NffqLDllirLgcCRjEgbeCaz9Gkn3Tu9e9F4=";
|
|
};
|
|
tomselect = fetchurl {
|
|
url = "https://cdn.jsdelivr.net/npm/tom-select@2.3.1/dist/js/tom-select.popular.min.js";
|
|
hash = "sha256-51NcdIM8GseVFFmg8mUWDxfhjLCA+n8kw/Ojyo+6Hjk=";
|
|
};
|
|
in
|
|
|
|
rustPlatform.buildRustPackage rec {
|
|
pname = "sqlpage";
|
|
version = "0.29.0";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "lovasoa";
|
|
repo = "SQLpage";
|
|
rev = "v${version}";
|
|
hash = "sha256-wI+nXrjX98vqyCE6Ofa5KxKUvpLfHqd7KFCsILuOnGk=";
|
|
};
|
|
|
|
postPatch = ''
|
|
substituteInPlace sqlpage/apexcharts.js \
|
|
--replace-fail '/* !include https://cdn.jsdelivr.net/npm/apexcharts@3.52.0/dist/apexcharts.min.js */' \
|
|
"$(cat ${apexcharts})"
|
|
substituteInPlace sqlpage/sqlpage.css \
|
|
--replace-fail '/* !include https://cdn.jsdelivr.net/npm/@tabler/core@1.0.0-beta20/dist/css/tabler.min.css */' \
|
|
"$(cat ${tablerCss})"
|
|
substituteInPlace sqlpage/sqlpage.css \
|
|
--replace-fail '/* !include https://cdn.jsdelivr.net/npm/@tabler/core@1.0.0-beta20/dist/css/tabler-vendors.min.css */' \
|
|
"$(cat ${tablerVendorsCss})"
|
|
substituteInPlace sqlpage/sqlpage.js \
|
|
--replace-fail '/* !include https://cdn.jsdelivr.net/npm/@tabler/core@1.0.0-beta20/dist/js/tabler.min.js */' \
|
|
"$(cat ${tablerJs})"
|
|
substituteInPlace sqlpage/sqlpage.js \
|
|
--replace-fail '/* !include https://cdn.jsdelivr.net/npm/list.js-fixed@2.3.4/dist/list.min.js */' \
|
|
"$(cat ${listJsFixed})"
|
|
substituteInPlace sqlpage/tabler-icons.svg \
|
|
--replace-fail '/* !include https://cdn.jsdelivr.net/npm/@tabler/icons-sprite@3.10.0/dist/tabler-sprite.svg */' \
|
|
"$(cat ${tablerIcons})"
|
|
substituteInPlace sqlpage/tomselect.js \
|
|
--replace-fail '/* !include https://cdn.jsdelivr.net/npm/tom-select@2.3.1/dist/js/tom-select.popular.min.js */' \
|
|
"$(cat ${tomselect})"
|
|
'';
|
|
|
|
cargoHash = "sha256-/B8tayEbyOsc0/po1YQKtp694X12B3I50OU4cMwJo8Q=";
|
|
|
|
nativeBuildInputs = [
|
|
pkg-config
|
|
];
|
|
|
|
buildInputs = [
|
|
sqlite
|
|
zstd
|
|
];
|
|
|
|
env = {
|
|
ZSTD_SYS_USE_PKG_CONFIG = true;
|
|
};
|
|
|
|
meta = {
|
|
description = "SQL-only webapp builder, empowering data analysts to build websites and applications quickly";
|
|
homepage = "https://github.com/lovasoa/SQLpage";
|
|
changelog = "https://github.com/lovasoa/SQLpage/blob/${src.rev}/CHANGELOG.md";
|
|
license = lib.licenses.mit;
|
|
maintainers = with lib.maintainers; [ dit7ya ];
|
|
mainProgram = "sqlpage";
|
|
};
|
|
}
|