mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-06 21:13:40 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
52 lines
1.3 KiB
Nix
52 lines
1.3 KiB
Nix
{ lib, buildGoModule, fetchFromGitHub, pkg-config, btrfs-progs, lvm2 }:
|
|
|
|
buildGoModule rec {
|
|
pname = "dockle";
|
|
version = "0.4.14";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "goodwithtech";
|
|
repo = pname;
|
|
rev = "v${version}";
|
|
hash = "sha256-ZAk51juPFSaDQYfzsf7HXigL4aIk8V+tGA9lZqHBOsY=";
|
|
};
|
|
|
|
vendorHash = "sha256-+AtvnplvPWkUwmxfB7rjYcLTQibQsObFT1QRR0FXAe0=";
|
|
|
|
nativeBuildInputs = [ pkg-config ];
|
|
buildInputs = [ btrfs-progs lvm2 ];
|
|
|
|
ldflags = [
|
|
"-s"
|
|
"-w"
|
|
"-X github.com/goodwithtech/dockle/pkg.version=${version}"
|
|
];
|
|
|
|
preCheck = ''
|
|
# Remove tests that use networking
|
|
rm pkg/scanner/scan_test.go
|
|
'';
|
|
|
|
doInstallCheck = true;
|
|
installCheckPhase = ''
|
|
runHook preInstallCheck
|
|
$out/bin/dockle --help
|
|
$out/bin/dockle --version | grep "dockle version ${version}"
|
|
runHook postInstallCheck
|
|
'';
|
|
|
|
meta = with lib; {
|
|
homepage = "https://containers.goodwith.tech";
|
|
changelog = "https://github.com/goodwithtech/dockle/releases/tag/v${version}";
|
|
description = "Container Image Linter for Security";
|
|
mainProgram = "dockle";
|
|
longDescription = ''
|
|
Container Image Linter for Security.
|
|
Helping build the Best-Practice Docker Image.
|
|
Easy to start.
|
|
'';
|
|
license = licenses.asl20;
|
|
maintainers = with maintainers; [ jk ];
|
|
};
|
|
}
|