mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-26 07:34:11 +00:00
4a7f99d55d
Part of: https://github.com/NixOS/nixpkgs/issues/108938 meta = with stdenv.lib; is a widely used pattern. We want to slowly remove the `stdenv.lib` indirection and encourage people to use `lib` directly. Thus let’s start with the meta field. This used a rewriting script to mostly automatically replace all occurances of this pattern, and add the `lib` argument to the package header if it doesn’t exist yet. The script in its current form is available at https://cs.tvl.fyi/depot@2f807d7f141068d2d60676a89213eaa5353ca6e0/-/blob/users/Profpatsch/nixpkgs-rewriter/default.nix
113 lines
3.9 KiB
Nix
113 lines
3.9 KiB
Nix
{ lib, stdenv, runtimeShell, pkgconfig, gettext, ncurses, CoreFoundation
|
|
, tiles, SDL2, SDL2_image, SDL2_mixer, SDL2_ttf, freetype, Cocoa
|
|
, debug
|
|
, useXdgDir
|
|
}:
|
|
|
|
let
|
|
inherit (stdenv.lib) optionals optionalString;
|
|
|
|
cursesDeps = [ gettext ncurses ]
|
|
++ optionals stdenv.isDarwin [ CoreFoundation ];
|
|
|
|
tilesDeps = [ SDL2 SDL2_image SDL2_mixer SDL2_ttf freetype ]
|
|
++ optionals stdenv.isDarwin [ Cocoa ];
|
|
|
|
installXDGAppLauncher = ''
|
|
launcher="$out/share/applications/cataclysm-dda.desktop"
|
|
install -D -m 444 data/xdg/*cataclysm-dda.desktop -T "$launcher"
|
|
sed -i "$launcher" -e "s,\(Exec=\)\(cataclysm-tiles\),\1$out/bin/\2,"
|
|
install -D -m 444 data/xdg/cataclysm-dda.svg -t $out/share/icons/hicolor/scalable/apps
|
|
'';
|
|
|
|
installMacOSAppLauncher = ''
|
|
app=$out/Applications/Cataclysm.app
|
|
install -D -m 444 data/osx/Info.plist -t $app/Contents
|
|
install -D -m 444 data/osx/AppIcon.icns -t $app/Contents/Resources
|
|
mkdir $app/Contents/MacOS
|
|
launcher=$app/Contents/MacOS/Cataclysm.sh
|
|
cat << EOF > $launcher
|
|
#!${runtimeShell}
|
|
$out/bin/cataclysm-tiles
|
|
EOF
|
|
chmod 555 $launcher
|
|
'';
|
|
in
|
|
|
|
stdenv.mkDerivation {
|
|
pname = "cataclysm-dda";
|
|
|
|
nativeBuildInputs = [ pkgconfig ];
|
|
|
|
buildInputs = cursesDeps ++ optionals tiles tilesDeps;
|
|
|
|
postPatch = ''
|
|
patchShebangs .
|
|
|
|
# Locale patch required for Darwin builds, see:
|
|
# https://github.com/NixOS/nixpkgs/pull/74064#issuecomment-560083970
|
|
sed -i src/translations.cpp \
|
|
-e 's@#elif (defined(__linux__) || (defined(MACOSX) && !defined(TILES)))@#elif 1@'
|
|
'';
|
|
|
|
makeFlags = [
|
|
"PREFIX=$(out)" "LANGUAGES=all"
|
|
(if useXdgDir then "USE_XDG_DIR=1" else "USE_HOME_DIR=1")
|
|
] ++ optionals (!debug) [
|
|
"RELEASE=1"
|
|
] ++ optionals tiles [
|
|
"TILES=1" "SOUND=1"
|
|
] ++ optionals stdenv.isDarwin [
|
|
"NATIVE=osx" "CLANG=1"
|
|
];
|
|
|
|
postInstall = optionalString tiles
|
|
( if !stdenv.isDarwin
|
|
then installXDGAppLauncher
|
|
else installMacOSAppLauncher
|
|
);
|
|
|
|
dontStrip = debug;
|
|
|
|
# https://hydra.nixos.org/build/65193254
|
|
# src/weather_data.cpp:203:1: fatal error: opening dependency file obj/tiles/weather_data.d: No such file or directory
|
|
# make: *** [Makefile:687: obj/tiles/weather_data.o] Error 1
|
|
enableParallelBuilding = false;
|
|
|
|
passthru = {
|
|
isTiles = tiles;
|
|
isCurses = !tiles;
|
|
};
|
|
|
|
meta = with lib; {
|
|
description = "A free, post apocalyptic, zombie infested rogue-like";
|
|
longDescription = ''
|
|
Cataclysm: Dark Days Ahead is a roguelike set in a post-apocalyptic world.
|
|
Surviving is difficult: you have been thrown, ill-equipped, into a
|
|
landscape now riddled with monstrosities of which flesh eating zombies are
|
|
neither the strangest nor the deadliest.
|
|
|
|
Yet with care and a little luck, many things are possible. You may try to
|
|
eke out an existence in the forests silently executing threats and
|
|
providing sustenance with your longbow. You can ride into town in a
|
|
jerry-rigged vehicle, all guns blazing, to settle matters in a fug of
|
|
smoke from your molotovs. You could take a more measured approach and
|
|
construct an impregnable fortress, surrounded by traps to protect you from
|
|
the horrors without. The longer you survive, the more skilled and adapted
|
|
you will get and the better equipped and armed to deal with the threats
|
|
you are presented with.
|
|
|
|
In the course of your ordeal there will be opportunities and temptations
|
|
to improve or change your very nature. There are tales of survivors fitted
|
|
with extraordinary cybernetics giving great power and stories too of
|
|
gravely mutated survivors who, warped by their ingestion of exotic
|
|
substances or radiation, now more closely resemble insects, birds or fish
|
|
than their original form.
|
|
'';
|
|
homepage = "https://cataclysmdda.org/";
|
|
license = licenses.cc-by-sa-30;
|
|
maintainers = with maintainers; [ mnacamura ];
|
|
platforms = platforms.unix;
|
|
};
|
|
}
|