mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-14 17:04:42 +00:00
4f0dadbf38
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build a08b3a4d19.tar.gz \
--argstr baseRev b32a094368
result/bin/apply-formatting $NIXPKGS_PATH
90 lines
2.3 KiB
Nix
90 lines
2.3 KiB
Nix
{ lib, stdenv }:
|
|
|
|
# This tests that libraries listed in LD_LIBRARY_PATH take precedence over those listed in RPATH.
|
|
|
|
let
|
|
# A simple test library: libgreeting.so which exports a single function getGreeting() returning the good old hello greeting.
|
|
libgreeting = stdenv.mkDerivation {
|
|
name = "libgreeting";
|
|
|
|
code = ''
|
|
const char* getGreeting() { return "Hello, world!"; }
|
|
'';
|
|
|
|
unpackPhase = ''
|
|
echo "$code" > libgreeting.c
|
|
'';
|
|
|
|
installPhase = ''
|
|
mkdir -p $out/lib
|
|
$CC -c -fpic libgreeting.c
|
|
$CC -shared libgreeting.o -o $out/lib/libgreeting.so
|
|
'';
|
|
};
|
|
|
|
# A variant of libgreeting.so that returns a different message.
|
|
libgoodbye = libgreeting.overrideAttrs (_: {
|
|
name = "libgoodbye";
|
|
code = ''
|
|
const char* getGreeting() { return "Goodbye, world!"; }
|
|
'';
|
|
});
|
|
|
|
# A simple consumer of libgreeting.so that just prints the greeting to stdout.
|
|
testProgram = stdenv.mkDerivation {
|
|
name = "greeting-test";
|
|
|
|
buildInputs = [ libgreeting ];
|
|
|
|
code = ''
|
|
#include <stdio.h>
|
|
|
|
extern const char* getGreeting(void);
|
|
|
|
int main() {
|
|
puts(getGreeting());
|
|
}
|
|
'';
|
|
|
|
unpackPhase = ''
|
|
echo "$code" > greeting-test.c
|
|
'';
|
|
|
|
installPhase = ''
|
|
mkdir -p $out/bin
|
|
$CC -c greeting-test.c
|
|
$CC greeting-test.o -lgreeting -o $out/bin/greeting-test
|
|
|
|
# Now test the installed binaries right after compiling them. In particular,
|
|
# don't do this in installCheckPhase because fixupPhase has been run by then!
|
|
(
|
|
export PATH=$out/bin
|
|
set -x
|
|
|
|
# Verify that our unmodified binary works as expected.
|
|
[ "$(greeting-test)" = "Hello, world!" ]
|
|
|
|
# And finally, test that a library in LD_LIBRARY_PATH takes precedence over the linked-in library.
|
|
[ "$(LD_LIBRARY_PATH=${libgoodbye}/lib greeting-test)" = "Goodbye, world!" ]
|
|
)
|
|
'';
|
|
|
|
};
|
|
in
|
|
stdenv.mkDerivation {
|
|
name = "test-LD_LIBRARY_PATH";
|
|
nativeBuildInputs = [ testProgram ];
|
|
|
|
buildCommand = ''
|
|
# And for good measure, repeat the tests again from a separate derivation,
|
|
# as fixupPhase done by the stdenv can (and has!) affect the result.
|
|
|
|
[ "$(greeting-test)" = "Hello, world!" ]
|
|
[ "$(LD_LIBRARY_PATH=${libgoodbye}/lib greeting-test)" = "Goodbye, world!" ]
|
|
|
|
touch $out
|
|
'';
|
|
|
|
meta.platforms = lib.platforms.linux;
|
|
}
|