mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-04 03:53:56 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
70 lines
2.2 KiB
Nix
70 lines
2.2 KiB
Nix
{ lib, stdenv, fetchurl, fetchpatch, pam, openssl, libkrb5 }:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "uw-imap";
|
|
version = "2007f";
|
|
|
|
src = fetchurl {
|
|
url = "ftp://ftp.cac.washington.edu/imap/imap-${version}.tar.gz";
|
|
sha256 = "0a2a00hbakh0640r2wdpnwr8789z59wnk7rfsihh3j0vbhmmmqak";
|
|
};
|
|
|
|
makeFlags = [
|
|
"CC=${stdenv.cc.targetPrefix}cc"
|
|
"RANLIB=${stdenv.cc.targetPrefix}ranlib"
|
|
(if stdenv.hostPlatform.isDarwin
|
|
then "osx"
|
|
else "lnp") # Linux with PAM modules;
|
|
] ++ lib.optional stdenv.hostPlatform.isx86_64 "EXTRACFLAGS=-fPIC"; # -fPIC is required to compile php with imap on x86_64 systems
|
|
|
|
|
|
hardeningDisable = [ "format" ];
|
|
|
|
buildInputs = [
|
|
openssl
|
|
(if stdenv.hostPlatform.isDarwin then libkrb5 else pam) # Matches the make target.
|
|
];
|
|
|
|
patches = [
|
|
(fetchpatch {
|
|
url = "https://salsa.debian.org/holmgren/uw-imap/raw/dcb42981201ea14c2d71c01ebb4a61691b6f68b3/debian/patches/1006_openssl1.1_autoverify.patch";
|
|
sha256 = "09xb58awvkhzmmjhrkqgijzgv7ia381ablf0y7i1rvhcqkb5wga7";
|
|
})
|
|
# Required to build with newer versions of clang. Fixes call to undeclared functions errors
|
|
# and incompatible function pointer conversions.
|
|
./clang-fix.patch
|
|
];
|
|
|
|
postPatch = ''
|
|
sed -i src/osdep/unix/Makefile -e 's,/usr/local/ssl,${openssl.dev},'
|
|
sed -i src/osdep/unix/Makefile -e 's,^SSLCERTS=.*,SSLCERTS=/etc/ssl/certs,'
|
|
sed -i src/osdep/unix/Makefile -e 's,^SSLLIB=.*,SSLLIB=${lib.getLib openssl}/lib,'
|
|
'';
|
|
|
|
preConfigure = ''
|
|
makeFlagsArray+=("ARRC=${stdenv.cc.targetPrefix}ar rc")
|
|
'';
|
|
|
|
env.NIX_CFLAGS_COMPILE = lib.optionalString stdenv.hostPlatform.isDarwin
|
|
"-I${openssl.dev}/include/openssl";
|
|
|
|
installPhase = ''
|
|
mkdir -p $out/bin $out/lib $out/include/c-client
|
|
cp c-client/*.h osdep/unix/*.h c-client/linkage.c c-client/auths.c $out/include/c-client/
|
|
cp c-client/c-client.a $out/lib/libc-client.a
|
|
cp mailutil/mailutil imapd/imapd dmail/dmail mlock/mlock mtest/mtest tmail/tmail \
|
|
tools/{an,ua} $out/bin
|
|
'';
|
|
|
|
meta = with lib; {
|
|
homepage = "https://www.washington.edu/imap/";
|
|
description = "UW IMAP toolkit - IMAP-supporting software developed by the UW";
|
|
license = licenses.asl20;
|
|
platforms = platforms.unix;
|
|
};
|
|
|
|
passthru = {
|
|
withSSL = true;
|
|
};
|
|
}
|