mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-02-22 03:53:47 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
41 lines
1.1 KiB
Nix
41 lines
1.1 KiB
Nix
{ lib, buildGoModule, fetchFromGitHub, installShellFiles, runCommand, yq-go }:
|
|
|
|
buildGoModule rec {
|
|
pname = "yq-go";
|
|
version = "4.44.3";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "mikefarah";
|
|
repo = "yq";
|
|
rev = "v${version}";
|
|
hash = "sha256-bQNa19K4wO2XoSecyfOQKTfHFTxkji1U42bL4k1G7Gg=";
|
|
};
|
|
|
|
vendorHash = "sha256-LsunMHKtyAkTAJhqURoAhIIyW//d37ZW4trr+x/Cd8U=";
|
|
|
|
nativeBuildInputs = [ installShellFiles ];
|
|
|
|
postInstall = ''
|
|
installShellCompletion --cmd yq \
|
|
--bash <($out/bin/yq shell-completion bash) \
|
|
--fish <($out/bin/yq shell-completion fish) \
|
|
--zsh <($out/bin/yq shell-completion zsh)
|
|
'';
|
|
|
|
passthru.tests = {
|
|
simple = runCommand "${pname}-test" { } ''
|
|
echo "test: 1" | ${yq-go}/bin/yq eval -j > $out
|
|
[ "$(cat $out | tr -d $'\n ')" = '{"test":1}' ]
|
|
'';
|
|
};
|
|
|
|
meta = with lib; {
|
|
description = "Portable command-line YAML processor";
|
|
homepage = "https://mikefarah.gitbook.io/yq/";
|
|
changelog = "https://github.com/mikefarah/yq/raw/v${version}/release_notes.txt";
|
|
mainProgram = "yq";
|
|
license = [ licenses.mit ];
|
|
maintainers = with maintainers; [ lewo SuperSandro2000 ];
|
|
};
|
|
}
|