mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-29 18:33:00 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
57 lines
1.2 KiB
Nix
57 lines
1.2 KiB
Nix
{ lib, stdenv
|
|
, fetchFromGitHub
|
|
, pkg-config
|
|
, autoreconfHook
|
|
, curl
|
|
, lua
|
|
, openssl
|
|
, features ? {
|
|
urls = false;
|
|
# Upstream enables regex by default
|
|
regex = true;
|
|
# Signature support is broken with openssl 1.1.1: https://github.com/vstakhov/libucl/issues/203
|
|
signatures = false;
|
|
lua = false;
|
|
utils = false;
|
|
}
|
|
}:
|
|
|
|
let
|
|
featureDeps = {
|
|
urls = [ curl ];
|
|
signatures = [ openssl ];
|
|
lua = [ lua ];
|
|
};
|
|
in
|
|
stdenv.mkDerivation rec {
|
|
pname = "libucl";
|
|
version = "0.9.2";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "vstakhov";
|
|
repo = pname;
|
|
rev = version;
|
|
sha256 = "sha256-esNEVBa660rl3Oo2SLaLrFThFkjbqtZ1r0tjMq3h6cM=";
|
|
};
|
|
|
|
nativeBuildInputs = [ pkg-config autoreconfHook ];
|
|
|
|
buildInputs = lib.concatLists (
|
|
lib.mapAttrsToList (feat: enabled:
|
|
lib.optionals enabled (featureDeps."${feat}" or [])
|
|
) features
|
|
);
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
configureFlags = lib.mapAttrsToList (feat: enabled: lib.strings.enableFeature enabled feat) features;
|
|
|
|
meta = with lib; {
|
|
description = "Universal configuration library parser";
|
|
homepage = "https://github.com/vstakhov/libucl";
|
|
license = licenses.bsd2;
|
|
platforms = platforms.unix;
|
|
maintainers = with maintainers; [ jpotier ];
|
|
};
|
|
}
|