mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-01 19:33:03 +00:00
6afb255d97
these changes were generated with nixq 0.0.2, by running nixq ">> lib.mdDoc[remove] Argument[keep]" --batchmode nixos/**.nix nixq ">> mdDoc[remove] Argument[keep]" --batchmode nixos/**.nix nixq ">> Inherit >> mdDoc[remove]" --batchmode nixos/**.nix two mentions of the mdDoc function remain in nixos/, both of which are inside of comments. Since lib.mdDoc is already defined as just id, this commit is a no-op as far as Nix (and the built manual) is concerned.
85 lines
2.3 KiB
Nix
85 lines
2.3 KiB
Nix
{ config, pkgs, lib, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
cfg = config.i18n.inputMethod.ibus;
|
|
ibusPackage = pkgs.ibus-with-plugins.override { plugins = cfg.engines; };
|
|
ibusEngine = types.package // {
|
|
name = "ibus-engine";
|
|
check = x: (lib.types.package.check x) && (attrByPath ["meta" "isIbusEngine"] false x);
|
|
};
|
|
|
|
impanel = optionalString (cfg.panel != null) "--panel=${cfg.panel}";
|
|
|
|
ibusAutostart = pkgs.writeTextFile {
|
|
name = "autostart-ibus-daemon";
|
|
destination = "/etc/xdg/autostart/ibus-daemon.desktop";
|
|
text = ''
|
|
[Desktop Entry]
|
|
Name=IBus
|
|
Type=Application
|
|
Exec=${ibusPackage}/bin/ibus-daemon --daemonize --xim ${impanel}
|
|
# GNOME will launch ibus using systemd
|
|
NotShowIn=GNOME;
|
|
'';
|
|
};
|
|
in
|
|
{
|
|
imports = [
|
|
(mkRenamedOptionModule [ "programs" "ibus" "plugins" ] [ "i18n" "inputMethod" "ibus" "engines" ])
|
|
];
|
|
|
|
options = {
|
|
i18n.inputMethod.ibus = {
|
|
engines = mkOption {
|
|
type = with types; listOf ibusEngine;
|
|
default = [];
|
|
example = literalExpression "with pkgs.ibus-engines; [ mozc hangul ]";
|
|
description =
|
|
let
|
|
enginesDrv = filterAttrs (const isDerivation) pkgs.ibus-engines;
|
|
engines = concatStringsSep ", "
|
|
(map (name: "`${name}`") (attrNames enginesDrv));
|
|
in "Enabled IBus engines. Available engines are: ${engines}.";
|
|
};
|
|
panel = mkOption {
|
|
type = with types; nullOr path;
|
|
default = null;
|
|
example = literalExpression ''"''${pkgs.plasma5Packages.plasma-desktop}/libexec/kimpanel-ibus-panel"'';
|
|
description = "Replace the IBus panel with another panel.";
|
|
};
|
|
};
|
|
};
|
|
|
|
config = mkIf (config.i18n.inputMethod.enabled == "ibus") {
|
|
i18n.inputMethod.package = ibusPackage;
|
|
|
|
environment.systemPackages = [
|
|
ibusAutostart
|
|
];
|
|
|
|
# Without dconf enabled it is impossible to use IBus
|
|
programs.dconf.enable = true;
|
|
|
|
programs.dconf.packages = [ ibusPackage ];
|
|
|
|
services.dbus.packages = [
|
|
ibusPackage
|
|
];
|
|
|
|
environment.variables = {
|
|
GTK_IM_MODULE = "ibus";
|
|
QT_IM_MODULE = "ibus";
|
|
XMODIFIERS = "@im=ibus";
|
|
};
|
|
|
|
xdg.portal.extraPortals = mkIf config.xdg.portal.enable [
|
|
ibusPackage
|
|
];
|
|
};
|
|
|
|
# uses attributes of the linked package
|
|
meta.buildDocsInSandbox = false;
|
|
}
|