mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-14 01:33:10 +00:00
33afbf39f6
checkInputs used to be added to nativeBuildInputs. Now we have nativeCheckInputs to do that instead. Doing this treewide change allows to keep hashes identical to before the introduction of nativeCheckInputs.
65 lines
1.4 KiB
Nix
65 lines
1.4 KiB
Nix
{ lib
|
|
, rustPlatform
|
|
, fetchFromGitHub
|
|
, cmake
|
|
, installShellFiles
|
|
, pkg-config
|
|
, zstd
|
|
, stdenv
|
|
, CoreFoundation
|
|
, libresolv
|
|
, Security
|
|
, git
|
|
}:
|
|
|
|
rustPlatform.buildRustPackage rec {
|
|
pname = "onefetch";
|
|
version = "2.15.1";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "o2sh";
|
|
repo = pname;
|
|
rev = version;
|
|
sha256 = "sha256-3wXZBPYths3+Vhtq4W2BTR47V63o0bq++fWLIpWrm7Y=";
|
|
};
|
|
|
|
cargoSha256 = "sha256-xBw2OMJMale4MWRyy6v0E0ZE4A98QXLyRu0k7L+9q8k=";
|
|
|
|
cargoPatches = [
|
|
# enable pkg-config feature of zstd
|
|
./zstd-pkg-config.patch
|
|
];
|
|
|
|
nativeBuildInputs = [ cmake installShellFiles pkg-config ];
|
|
|
|
buildInputs = [ zstd ]
|
|
++ lib.optionals stdenv.isDarwin [ CoreFoundation libresolv Security ];
|
|
|
|
nativeCheckInputs = [
|
|
git
|
|
];
|
|
|
|
preCheck = ''
|
|
git init
|
|
git config user.name nixbld
|
|
git config user.email nixbld@example.com
|
|
git add .
|
|
git commit -m test
|
|
'';
|
|
|
|
postInstall = ''
|
|
installShellCompletion --cmd onefetch \
|
|
--bash <($out/bin/onefetch --generate bash) \
|
|
--fish <($out/bin/onefetch --generate fish) \
|
|
--zsh <($out/bin/onefetch --generate zsh)
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Git repository summary on your terminal";
|
|
homepage = "https://github.com/o2sh/onefetch";
|
|
changelog = "https://github.com/o2sh/onefetch/blob/v${version}/CHANGELOG.md";
|
|
license = licenses.mit;
|
|
maintainers = with maintainers; [ Br1ght0ne figsoda kloenk SuperSandro2000 ];
|
|
};
|
|
}
|