mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-26 17:03:01 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
48 lines
1.3 KiB
Nix
48 lines
1.3 KiB
Nix
{ lib, stdenv, fetchFromGitHub
|
|
, cmake
|
|
}:
|
|
stdenv.mkDerivation rec {
|
|
pname = "bento4";
|
|
version = "1.6.0-641";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "axiomatic-systems";
|
|
repo = "Bento4";
|
|
rev = "v${version}";
|
|
hash = "sha256-Qy8D3cbCVHmLAaXtiF64rL2oRurXNCtd5Dsgt0W7WdY=";
|
|
};
|
|
|
|
patches = [
|
|
./libap4.patch # include all libraries as shared, not static
|
|
];
|
|
|
|
nativeBuildInputs = [ cmake ];
|
|
|
|
cmakeFlags = [
|
|
"-DBUILD_SHARED_LIBS=ON"
|
|
] ++ lib.optionals stdenv.hostPlatform.isDarwin [
|
|
"-DCMAKE_OSX_ARCHITECTURES="
|
|
];
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
mkdir -p $out/{lib,bin}
|
|
find -iname '*${stdenv.hostPlatform.extensions.sharedLibrary}' -exec mv --target-directory="$out/lib" {} \;
|
|
find -maxdepth 1 -executable -type f -exec mv --target-directory="$out/bin" {} \;
|
|
runHook postInstall
|
|
'';
|
|
|
|
# Patch binaries to use our dylib
|
|
postInstall = lib.optionalString stdenv.hostPlatform.isDarwin ''
|
|
find $out/bin -maxdepth 1 -executable -type f -exec install_name_tool -change @rpath/libap4.dylib $out/lib/libap4.dylib {} \;
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Full-featured MP4 format and MPEG DASH library and tools";
|
|
homepage = "http://bento4.com";
|
|
license = licenses.gpl2Plus;
|
|
maintainers = with maintainers; [ makefu ];
|
|
platforms = platforms.unix;
|
|
};
|
|
}
|