mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-06 04:53:27 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
40 lines
1.3 KiB
Nix
40 lines
1.3 KiB
Nix
{ lib, stdenvNoCC, fetchFromGitHub, shellspec, busybox-sandbox-shell, ksh, mksh, yash, zsh }:
|
|
|
|
stdenvNoCC.mkDerivation rec {
|
|
pname = "getoptions";
|
|
version = "3.3.2";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "ko1nksm";
|
|
repo = "getoptions";
|
|
rev = "v${version}";
|
|
hash = "sha256-hapOGPibqt2Mm6k73v63gHxrX+lifZ8xcwzj8vWbtgo=";
|
|
};
|
|
|
|
makeFlags = [ "PREFIX=${placeholder "out"}" ];
|
|
|
|
doCheck = true;
|
|
|
|
nativeCheckInputs = [ shellspec ksh mksh yash zsh ]
|
|
++ lib.lists.optional (!stdenvNoCC.hostPlatform.isDarwin) busybox-sandbox-shell;
|
|
|
|
# Disable checks against yash, since shellspec seems to be broken for yash>=2.54
|
|
# (see: https://github.com/NixOS/nixpkgs/pull/218264#pullrequestreview-1434402054)
|
|
preCheck = ''
|
|
sed -i '/shellspec -s posh/d' Makefile
|
|
sed -i '/shellspec -s yash/d' Makefile
|
|
'' + lib.strings.optionalString stdenvNoCC.hostPlatform.isDarwin ''
|
|
sed -i "/shellspec -s 'busybox ash'/d" Makefile
|
|
'';
|
|
|
|
checkTarget = "test_in_various_shells";
|
|
|
|
meta = with lib; {
|
|
description = "Elegant option/argument parser for shell scripts (full support for bash and all POSIX shells)";
|
|
homepage = "https://github.com/ko1nksm/getoptions";
|
|
license = licenses.cc0;
|
|
platforms = platforms.all;
|
|
maintainers = with maintainers; [ matrss ];
|
|
};
|
|
}
|