mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-06 04:53:27 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
57 lines
1.4 KiB
Nix
57 lines
1.4 KiB
Nix
{ lib
|
|
, stdenv
|
|
, fetchFromGitHub
|
|
, cmake
|
|
, ninja
|
|
# Enable C++17 support
|
|
# https://github.com/google/googletest/issues/3081
|
|
# Projects that require a higher standard can override this package.
|
|
# For an example why that may be necessary, see:
|
|
# https://github.com/mhx/dwarfs/issues/188#issuecomment-1907574427
|
|
# Setting this to `null` does not pass any flags to set this.
|
|
, cxx_standard ? (
|
|
if (
|
|
(stdenv.cc.isGNU && (lib.versionOlder stdenv.cc.version "11.0"))
|
|
||
|
|
(stdenv.cc.isClang && (lib.versionOlder stdenv.cc.version "16.0"))
|
|
)
|
|
then "17"
|
|
else null
|
|
)
|
|
, static ? stdenv.hostPlatform.isStatic,
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "gtest";
|
|
version = "1.15.2";
|
|
|
|
outputs = [ "out" "dev" ];
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "google";
|
|
repo = "googletest";
|
|
rev = "v${version}";
|
|
hash = "sha256-1OJ2SeSscRBNr7zZ/a8bJGIqAnhkg45re0j3DtPfcXM=";
|
|
};
|
|
|
|
patches = [
|
|
./fix-cmake-config-includedir.patch
|
|
];
|
|
|
|
nativeBuildInputs = [ cmake ninja ];
|
|
|
|
cmakeFlags = [
|
|
"-DBUILD_SHARED_LIBS=${if static then "OFF" else "ON"}"
|
|
] ++ lib.optionals (cxx_standard != null) [
|
|
"-DCMAKE_CXX_STANDARD=${cxx_standard}"
|
|
];
|
|
|
|
meta = with lib; {
|
|
description = "Google's framework for writing C++ tests";
|
|
homepage = "https://github.com/google/googletest";
|
|
license = licenses.bsd3;
|
|
platforms = platforms.all;
|
|
maintainers = with maintainers; [ ivan-tkatchev ];
|
|
};
|
|
}
|