mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-13 09:13:17 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
80 lines
2.6 KiB
Nix
80 lines
2.6 KiB
Nix
{ lib
|
|
, stdenv
|
|
, cmake
|
|
, ninja
|
|
, gtest
|
|
, fetchFromGitHub
|
|
, fetchpatch
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "libhwy";
|
|
version = "1.0.7";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "google";
|
|
repo = "highway";
|
|
rev = version;
|
|
hash = "sha256-Z+mAR9nSAbCskUvo6oK79Yd85bu0HtI2aR5THS1EozM=";
|
|
};
|
|
|
|
patches = lib.optional stdenv.hostPlatform.isRiscV
|
|
# Adds CMake option HWY_CMAKE_RVV
|
|
# https://github.com/google/highway/pull/1743
|
|
(fetchpatch {
|
|
name = "libhwy-add-rvv-optout.patch";
|
|
url = "https://github.com/google/highway/commit/5d58d233fbcec0c6a39df8186a877329147324b3.patch";
|
|
hash = "sha256-ileSNYddOt1F5rooRB0fXT20WkVlnG+gP5w7qJdBuww=";
|
|
});
|
|
|
|
hardeningDisable = lib.optionals stdenv.hostPlatform.isAarch64 [
|
|
# aarch64-specific code gets:
|
|
# __builtin_clear_padding not supported for variable length aggregates
|
|
"trivialautovarinit"
|
|
];
|
|
|
|
nativeBuildInputs = [ cmake ninja ];
|
|
|
|
# Required for case-insensitive filesystems ("BUILD" exists)
|
|
dontUseCmakeBuildDir = true;
|
|
|
|
cmakeFlags = let
|
|
libExt = stdenv.hostPlatform.extensions.library;
|
|
in [
|
|
"-GNinja"
|
|
"-DCMAKE_INSTALL_LIBDIR=lib"
|
|
"-DCMAKE_INSTALL_INCLUDEDIR=include"
|
|
] ++ lib.optionals doCheck [
|
|
"-DHWY_SYSTEM_GTEST:BOOL=ON"
|
|
"-DGTEST_INCLUDE_DIR=${lib.getDev gtest}/include"
|
|
"-DGTEST_LIBRARY=${lib.getLib gtest}/lib/libgtest${libExt}"
|
|
"-DGTEST_MAIN_LIBRARY=${lib.getLib gtest}/lib/libgtest_main${libExt}"
|
|
] ++ lib.optionals stdenv.hostPlatform.isAarch32 [
|
|
"-DHWY_CMAKE_ARM7=ON"
|
|
] ++ lib.optionals stdenv.hostPlatform.isx86_32 [
|
|
# Quoting CMakelists.txt:
|
|
# This must be set on 32-bit x86 with GCC < 13.1, otherwise math_test will be
|
|
# skipped. For GCC 13.1+, you can also build with -fexcess-precision=standard.
|
|
# Fixes tests:
|
|
# HwyMathTestGroup/HwyMathTest.TestAllAtanh/EMU128
|
|
# HwyMathTestGroup/HwyMathTest.TestAllLog1p/EMU128
|
|
"-DHWY_CMAKE_SSE2=ON"
|
|
] ++ lib.optionals stdenv.hostPlatform.isRiscV [
|
|
# Runtime dispatch is not implemented https://github.com/google/highway/issues/838
|
|
# so tests (and likely normal operation) fail with SIGILL on processors without V.
|
|
# Until the issue is resolved, we disable RVV completely.
|
|
"-DHWY_CMAKE_RVV=OFF"
|
|
];
|
|
|
|
# hydra's darwin machines run into https://github.com/libjxl/libjxl/issues/408
|
|
doCheck = !stdenv.hostPlatform.isDarwin;
|
|
|
|
meta = with lib; {
|
|
description = "Performance-portable, length-agnostic SIMD with runtime dispatch";
|
|
homepage = "https://github.com/google/highway";
|
|
license = with licenses; [ asl20 bsd3 ];
|
|
platforms = platforms.unix;
|
|
maintainers = with maintainers; [ zhaofengli ];
|
|
};
|
|
}
|