mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-28 16:43:58 +00:00
4f0dadbf38
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build a08b3a4d19.tar.gz \
--argstr baseRev b32a094368
result/bin/apply-formatting $NIXPKGS_PATH
77 lines
2.3 KiB
Nix
77 lines
2.3 KiB
Nix
{
|
||
lib,
|
||
stdenv,
|
||
fetchurl,
|
||
ncurses,
|
||
pkg-config,
|
||
autoreconfHook,
|
||
|
||
# `ps` with systemd support is able to properly report different
|
||
# attributes like unit name, so we want to have it on linux.
|
||
withSystemd ? lib.meta.availableOn stdenv.hostPlatform systemd,
|
||
systemd,
|
||
|
||
# procps is mostly Linux-only. Most commands require a running Linux
|
||
# system (or very similar like that found in Cygwin). The one
|
||
# exception is ‘watch’ which is portable enough to run on pretty much
|
||
# any UNIX-compatible system.
|
||
watchOnly ? !(stdenv.hostPlatform.isLinux || stdenv.hostPlatform.isCygwin),
|
||
|
||
binlore,
|
||
procps,
|
||
}:
|
||
|
||
stdenv.mkDerivation rec {
|
||
pname = "procps";
|
||
version = "4.0.4";
|
||
|
||
# The project's releases are on SF, but git repo on gitlab.
|
||
src = fetchurl {
|
||
url = "mirror://sourceforge/procps-ng/procps-ng-${version}.tar.xz";
|
||
hash = "sha256-IocNb+skeK22F85PCaeHrdry0mDFqKp7F9iJqWLF5C4=";
|
||
};
|
||
|
||
buildInputs = [ ncurses ] ++ lib.optional withSystemd systemd;
|
||
nativeBuildInputs = [
|
||
pkg-config
|
||
autoreconfHook
|
||
];
|
||
|
||
makeFlags = [ "usrbin_execdir=$(out)/bin" ] ++ lib.optionals watchOnly [ "src/watch" ];
|
||
|
||
enableParallelBuilding = true;
|
||
|
||
# Too red; 8bit support for fixing https://github.com/NixOS/nixpkgs/issues/275220
|
||
configureFlags =
|
||
[
|
||
"--disable-modern-top"
|
||
"--enable-watch8bit"
|
||
]
|
||
++ lib.optional withSystemd "--with-systemd"
|
||
++ lib.optional stdenv.hostPlatform.isMusl "--disable-w"
|
||
++ lib.optionals (stdenv.hostPlatform != stdenv.buildPlatform) [
|
||
"ac_cv_func_malloc_0_nonnull=yes"
|
||
"ac_cv_func_realloc_0_nonnull=yes"
|
||
];
|
||
|
||
installPhase = lib.optionalString watchOnly ''
|
||
install -m 0755 -D src/watch $out/bin/watch
|
||
install -m 0644 -D man/watch.1 $out/share/man/man1/watch.1
|
||
'';
|
||
|
||
# no obvious exec in documented arguments; haven't trawled source
|
||
# to figure out what exec binlore hits on
|
||
passthru.binlore.out = binlore.synthesize procps ''
|
||
execer cannot bin/{ps,top,free}
|
||
'';
|
||
|
||
meta = with lib; {
|
||
homepage = "https://gitlab.com/procps-ng/procps";
|
||
description = "Utilities that give information about processes using the /proc filesystem";
|
||
priority = 11; # less than coreutils, which also provides "kill" and "uptime"
|
||
license = licenses.gpl2Plus;
|
||
platforms = platforms.unix;
|
||
maintainers = [ ];
|
||
};
|
||
}
|