mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-13 08:23:25 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
56 lines
1.3 KiB
Nix
56 lines
1.3 KiB
Nix
{ lib, stdenv
|
|
, cmake
|
|
, fetchurl
|
|
, perl
|
|
, zlib
|
|
, groff
|
|
, withBzip2 ? false
|
|
, bzip2
|
|
, withLZMA ? false
|
|
, xz
|
|
, withOpenssl ? false
|
|
, openssl
|
|
, withZstd ? false
|
|
, zstd
|
|
, testers
|
|
}:
|
|
|
|
stdenv.mkDerivation (finalAttrs: {
|
|
pname = "libzip";
|
|
version = "1.11.1";
|
|
|
|
src = fetchurl {
|
|
url = "https://libzip.org/download/libzip-${finalAttrs.version}.tar.gz";
|
|
hash = "sha256-wOb6UqYroR79MCYikNxpcJR67zLgzClO5Q6QBc6sCSo=";
|
|
};
|
|
|
|
outputs = [ "out" "dev" "man" ];
|
|
|
|
nativeBuildInputs = [ cmake perl groff ];
|
|
propagatedBuildInputs = [ zlib ];
|
|
buildInputs = lib.optionals withLZMA [ xz ]
|
|
++ lib.optionals withBzip2 [ bzip2 ]
|
|
++ lib.optionals withOpenssl [ openssl ]
|
|
++ lib.optionals withZstd [ zstd ];
|
|
|
|
# Don't build the regression tests because they don't build with
|
|
# pkgsStatic and are not executed anyway.
|
|
cmakeFlags = [ "-DBUILD_REGRESS=0" ];
|
|
|
|
preCheck = ''
|
|
# regress/runtest is a generated file
|
|
patchShebangs regress
|
|
'';
|
|
|
|
passthru.tests.pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
|
|
|
|
meta = with lib; {
|
|
homepage = "https://libzip.org/";
|
|
description = "C library for reading, creating and modifying zip archives";
|
|
license = licenses.bsd3;
|
|
pkgConfigModules = [ "libzip" ];
|
|
platforms = platforms.unix;
|
|
changelog = "https://github.com/nih-at/libzip/blob/v${finalAttrs.version}/NEWS.md";
|
|
};
|
|
})
|