mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-04 03:53:56 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
48 lines
1.3 KiB
Nix
48 lines
1.3 KiB
Nix
{ lib
|
|
, rustPlatform
|
|
, fetchCrate
|
|
, installShellFiles
|
|
, stdenv
|
|
, nix-update-script
|
|
, callPackage
|
|
}:
|
|
|
|
rustPlatform.buildRustPackage rec {
|
|
pname = "cargo-show-asm";
|
|
version = "0.2.41";
|
|
|
|
src = fetchCrate {
|
|
inherit pname version;
|
|
hash = "sha256-U9i/xp9WxMYf4GMsZB7qYOpuuuEw4mWZp+ZEyguGtQQ=";
|
|
};
|
|
|
|
cargoHash = "sha256-eUaEpex9x9bdqPJ4p5QvkWKaxs3ih4Gb9+4deGBZgXU=";
|
|
|
|
nativeBuildInputs = [
|
|
installShellFiles
|
|
];
|
|
|
|
postInstall = lib.optionalString (stdenv.buildPlatform.canExecute stdenv.hostPlatform) ''
|
|
installShellCompletion --cmd cargo-asm \
|
|
--bash <($out/bin/cargo-asm --bpaf-complete-style-bash) \
|
|
--fish <($out/bin/cargo-asm --bpaf-complete-style-fish) \
|
|
--zsh <($out/bin/cargo-asm --bpaf-complete-style-zsh)
|
|
'';
|
|
|
|
passthru = {
|
|
updateScript = nix-update-script { };
|
|
tests = lib.optionalAttrs stdenv.hostPlatform.isx86_64 {
|
|
test-basic-x86_64 = callPackage ./test-basic-x86_64.nix { };
|
|
};
|
|
};
|
|
|
|
meta = with lib; {
|
|
description = "Cargo subcommand showing the assembly, LLVM-IR and MIR generated for Rust code";
|
|
homepage = "https://github.com/pacak/cargo-show-asm";
|
|
changelog = "https://github.com/pacak/cargo-show-asm/blob/${version}/Changelog.md";
|
|
license = with licenses; [ asl20 mit ];
|
|
maintainers = with maintainers; [ figsoda oxalica matthiasbeyer ];
|
|
mainProgram = "cargo-asm";
|
|
};
|
|
}
|