mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-27 01:13:05 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
58 lines
1.7 KiB
Nix
58 lines
1.7 KiB
Nix
{ lib, stdenv, nixosTests, fetchFromGitHub, pam, openssl, perl }:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "pam_ssh_agent_auth";
|
|
version = "0.10.4";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "jbeverly";
|
|
repo = "pam_ssh_agent_auth";
|
|
rev = "pam_ssh_agent_auth-${version}";
|
|
sha256 = "YD1R8Cox0UoNiuWleKGzWSzxJ5lhDRCB2mZPp9OM6Cs=";
|
|
};
|
|
|
|
ed25519-donna = fetchFromGitHub {
|
|
owner = "floodyberry";
|
|
repo = "ed25519-donna";
|
|
rev = "8757bd4cd209cb032853ece0ce413f122eef212c";
|
|
sha256 = "ETFpIaWQnlYG8ZuDG2dNjUJddlvibB4ukHquTFn3NZM=";
|
|
};
|
|
|
|
buildInputs = [ pam openssl perl ];
|
|
|
|
patches = [
|
|
# Allow multiple colon-separated authorized keys files to be
|
|
# specified in the file= option.
|
|
./multiple-key-files.patch
|
|
./edcsa-crash-fix.patch
|
|
];
|
|
|
|
configureFlags = [
|
|
# It's not clear to me why this is necessary, but without it, you see:
|
|
#
|
|
# checking OpenSSL header version... 1010108f (OpenSSL 1.1.1h 22 Sep 2020)
|
|
# checking OpenSSL library version... 1010108f (OpenSSL 1.1.1h 22 Sep 2020)
|
|
# checking whether OpenSSL's headers match the library... no
|
|
# configure: WARNING: Your OpenSSL headers do not match your
|
|
# library. Check config.log for details.
|
|
#
|
|
# ...despite the fact that clearly the values match
|
|
"--without-openssl-header-check"
|
|
# Make sure it can find ed25519-donna
|
|
"--with-cflags=-I$PWD"
|
|
];
|
|
|
|
prePatch = "cp -r ${ed25519-donna}/. ed25519-donna/.";
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
passthru.tests.sudo = nixosTests.ssh-agent-auth;
|
|
|
|
meta = {
|
|
homepage = "https://github.com/jbeverly/pam_ssh_agent_auth";
|
|
description = "PAM module for authentication through the SSH agent";
|
|
maintainers = [ ];
|
|
platforms = lib.platforms.linux;
|
|
};
|
|
}
|