mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-06 04:53:27 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
82 lines
2.6 KiB
Nix
82 lines
2.6 KiB
Nix
{ stdenv, lib, writeScript, qt5, fetchurl, autoPatchelfHook, dpkg, glibc, cpio, xar, undmg, gtk3, pango, libxcb }:
|
|
let
|
|
pname = "synology-drive-client";
|
|
baseUrl = "https://global.synologydownload.com/download/Utility/SynologyDriveClient";
|
|
version = "3.5.1-16101";
|
|
buildNumber = lib.last (lib.splitString "-" version);
|
|
meta = with lib; {
|
|
description = "Desktop application to synchronize files and folders between the computer and the Synology Drive server";
|
|
homepage = "https://www.synology.com/en-global/dsm/feature/drive";
|
|
sourceProvenance = with sourceTypes; [ binaryNativeCode ];
|
|
license = licenses.unfree;
|
|
maintainers = with maintainers; [ jcouyang MoritzBoehme ];
|
|
platforms = [ "x86_64-linux" "x86_64-darwin" "aarch64-darwin" ];
|
|
mainProgram = "synology-drive";
|
|
};
|
|
passthru.updateScript = writeScript "update-synology-drive-client" ''
|
|
#!/usr/bin/env nix-shell
|
|
#!nix-shell -i bash -p curl common-updater-scripts
|
|
|
|
set -eu -o pipefail
|
|
|
|
version="$(curl -s https://www.synology.com/en-uk/releaseNote/SynologyDriveClient \
|
|
| grep -oP '(?<=data-version=")(\d.){2}\d-\d{5}' \
|
|
| head -1)"
|
|
update-source-version synology-drive-client "$version"
|
|
'';
|
|
|
|
linux = stdenv.mkDerivation {
|
|
inherit pname version meta passthru;
|
|
|
|
src = fetchurl {
|
|
url = "${baseUrl}/${version}/Ubuntu/Installer/synology-drive-client-${buildNumber}.x86_64.deb";
|
|
sha256 = "sha256-VeS5bPcMM4JDCSH5GXkl4OgQjrPKaNDh5PfX28/zqaU=";
|
|
};
|
|
|
|
nativeBuildInputs = [ qt5.wrapQtAppsHook autoPatchelfHook dpkg ];
|
|
|
|
buildInputs = [ glibc gtk3 pango libxcb ];
|
|
|
|
unpackPhase = ''
|
|
mkdir -p $out
|
|
dpkg -x $src $out
|
|
rm -rf $out/usr/lib/nautilus
|
|
rm -rf $out/opt/Synology/SynologyDrive/package/cloudstation/icon-overlay
|
|
'';
|
|
|
|
installPhase = ''
|
|
cp -av $out/usr/* $out
|
|
rm -rf $out/usr
|
|
runHook postInstall
|
|
'';
|
|
|
|
postInstall = ''
|
|
substituteInPlace $out/bin/synology-drive --replace /opt $out/opt
|
|
'';
|
|
};
|
|
|
|
darwin = stdenv.mkDerivation {
|
|
inherit pname version meta passthru;
|
|
|
|
src = fetchurl {
|
|
url = "${baseUrl}/${version}/Mac/Installer/synology-drive-client-${buildNumber}.dmg";
|
|
sha256 = "sha256-VyhROpQCeVHNxxYgPUZdAlng15aJ1/IYadz30FThlsw=";
|
|
};
|
|
|
|
nativeBuildInputs = [ cpio xar undmg ];
|
|
|
|
postUnpack = ''
|
|
xar -xf 'Install Synology Drive Client.pkg'
|
|
cd synology-drive.installer.pkg
|
|
gunzip -dc Payload | cpio -i
|
|
'';
|
|
|
|
sourceRoot = ".";
|
|
|
|
installPhase = ''
|
|
mkdir -p $out/Applications/
|
|
cp -R 'Synology Drive Client.app' $out/Applications/
|
|
'';
|
|
};
|
|
in if stdenv.hostPlatform.isDarwin then darwin else linux
|