mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-06 04:53:27 +00:00
4f0dadbf38
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build a08b3a4d19.tar.gz \
--argstr baseRev b32a094368
result/bin/apply-formatting $NIXPKGS_PATH
79 lines
2.0 KiB
Nix
79 lines
2.0 KiB
Nix
{
|
||
stdenv,
|
||
lib,
|
||
buildGoModule,
|
||
fetchFromGitHub,
|
||
installShellFiles,
|
||
testers,
|
||
kubeshark,
|
||
nix-update-script,
|
||
}:
|
||
|
||
buildGoModule rec {
|
||
pname = "kubeshark";
|
||
version = "52.3.91";
|
||
|
||
src = fetchFromGitHub {
|
||
owner = "kubeshark";
|
||
repo = "kubeshark";
|
||
rev = "v${version}";
|
||
hash = "sha256-xkfEhCkG2qnoMZ7l48mK56PemtQBHK46p4jLxR9GHxc=";
|
||
};
|
||
|
||
vendorHash = "sha256-kzyQW4bVE7oMOlHVG7LKG1AMTRYa5GLiiEhdarIhMSo=";
|
||
|
||
ldflags =
|
||
let
|
||
t = "github.com/kubeshark/kubeshark";
|
||
in
|
||
[
|
||
"-s"
|
||
"-w"
|
||
"-X ${t}/misc.GitCommitHash=${src.rev}"
|
||
"-X ${t}/misc.Branch=master"
|
||
"-X ${t}/misc.BuildTimestamp=0"
|
||
"-X ${t}/misc.Platform=unknown"
|
||
"-X ${t}/misc.Ver=${version}"
|
||
];
|
||
|
||
nativeBuildInputs = [ installShellFiles ];
|
||
|
||
checkPhase = ''
|
||
go test ./...
|
||
'';
|
||
doCheck = true;
|
||
|
||
postInstall = lib.optionalString (stdenv.buildPlatform.canExecute stdenv.hostPlatform) ''
|
||
installShellCompletion --cmd kubeshark \
|
||
--bash <($out/bin/kubeshark completion bash) \
|
||
--fish <($out/bin/kubeshark completion fish) \
|
||
--zsh <($out/bin/kubeshark completion zsh)
|
||
'';
|
||
|
||
passthru = {
|
||
tests.version = testers.testVersion {
|
||
package = kubeshark;
|
||
command = "kubeshark version";
|
||
inherit version;
|
||
};
|
||
updateScript = nix-update-script { };
|
||
};
|
||
|
||
meta = with lib; {
|
||
changelog = "https://github.com/kubeshark/kubeshark/releases/tag/${version}";
|
||
description = "API Traffic Viewer for Kubernetes";
|
||
mainProgram = "kubeshark";
|
||
homepage = "https://kubeshark.co/";
|
||
license = licenses.asl20;
|
||
longDescription = ''
|
||
The API traffic viewer for Kubernetes providing real-time, protocol-aware visibility into Kubernetes’ internal network,
|
||
Think TCPDump and Wireshark re-invented for Kubernetes
|
||
capturing, dissecting and monitoring all traffic and payloads going in, out and across containers, pods, nodes and clusters.
|
||
'';
|
||
maintainers = with maintainers; [
|
||
bryanasdev000
|
||
qjoly
|
||
];
|
||
};
|
||
}
|