mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-02-04 03:03:42 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
47 lines
1.3 KiB
Nix
47 lines
1.3 KiB
Nix
{ lib, rustPlatform, fetchFromGitHub, installShellFiles, stdenv }:
|
|
|
|
rustPlatform.buildRustPackage rec {
|
|
pname = "jrsonnet";
|
|
version = "0.4.2";
|
|
|
|
src = fetchFromGitHub {
|
|
rev = "v${version}";
|
|
owner = "CertainLach";
|
|
repo = "jrsonnet";
|
|
sha256 = "sha256-OX+iJJ3vdCsWWr8x31psV9Vne6xWDZnJc83NbJqMK1A=";
|
|
};
|
|
|
|
cargoLock = {
|
|
lockFile = ./Cargo.lock;
|
|
outputHashes = {
|
|
"clap-3.0.0-beta.2" = "sha256-BaLzm2JZEicktfsCIXQipHtEKlEv2lBktfvHP58rjeM=";
|
|
};
|
|
};
|
|
|
|
nativeBuildInputs = [ installShellFiles ];
|
|
|
|
# skip flaky tests
|
|
checkFlags = [
|
|
"--skip=tests::native_ext"
|
|
];
|
|
|
|
postInstall = ''
|
|
ln -s $out/bin/jrsonnet $out/bin/jsonnet
|
|
|
|
'' + lib.optionalString (stdenv.buildPlatform.canExecute stdenv.hostPlatform) ''
|
|
for shell in bash zsh fish; do
|
|
installShellCompletion --cmd jrsonnet \
|
|
--$shell <($out/bin/jrsonnet --generate $shell /dev/null)
|
|
installShellCompletion --cmd jsonnet \
|
|
--$shell <($out/bin/jrsonnet --generate $shell /dev/null | sed s/jrsonnet/jsonnet/g)
|
|
done
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Purely-functional configuration language that helps you define JSON data";
|
|
homepage = "https://github.com/CertainLach/jrsonnet";
|
|
license = licenses.mit;
|
|
maintainers = with maintainers; [ figsoda lach ];
|
|
};
|
|
}
|