mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-29 09:04:17 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
46 lines
1.4 KiB
Nix
46 lines
1.4 KiB
Nix
{ lib, stdenv, fetchFromGitHub, fixDarwinDylibNames, oracle-instantclient, libaio }:
|
|
|
|
let
|
|
version = "5.4.0";
|
|
libPath = lib.makeLibraryPath [ oracle-instantclient.lib ];
|
|
|
|
in
|
|
stdenv.mkDerivation {
|
|
inherit version;
|
|
|
|
pname = "odpic";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "oracle";
|
|
repo = "odpi";
|
|
rev = "v${version}";
|
|
sha256 = "sha256-MmzForjAgccze7VvNcN6vX4rfiy+W9eGQ2Qh49ah7Ps=";
|
|
};
|
|
|
|
nativeBuildInputs = lib.optional stdenv.hostPlatform.isDarwin fixDarwinDylibNames;
|
|
|
|
buildInputs = [ oracle-instantclient ]
|
|
++ lib.optionals stdenv.hostPlatform.isLinux [ libaio ];
|
|
|
|
dontPatchELF = true;
|
|
makeFlags = [ "PREFIX=$(out)" "CC=${stdenv.cc.targetPrefix}cc" "LD=${stdenv.cc.targetPrefix}cc" ];
|
|
|
|
postFixup = ''
|
|
${lib.optionalString (stdenv.hostPlatform.isLinux) ''
|
|
patchelf --set-rpath "${libPath}:$(patchelf --print-rpath $out/lib/libodpic${stdenv.hostPlatform.extensions.sharedLibrary})" $out/lib/libodpic${stdenv.hostPlatform.extensions.sharedLibrary}
|
|
''}
|
|
${lib.optionalString (stdenv.hostPlatform.isDarwin) ''
|
|
install_name_tool -add_rpath "${libPath}" $out/lib/libodpic${stdenv.hostPlatform.extensions.sharedLibrary}
|
|
''}
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Oracle ODPI-C library";
|
|
homepage = "https://oracle.github.io/odpi/";
|
|
maintainers = with maintainers; [ mkazulak ];
|
|
license = licenses.asl20;
|
|
platforms = [ "x86_64-linux" "aarch64-linux" "x86_64-darwin" ];
|
|
hydraPlatforms = [ ];
|
|
};
|
|
}
|