mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-29 09:04:17 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
64 lines
1.9 KiB
Nix
64 lines
1.9 KiB
Nix
{ lib, stdenv, buildPackages, fetchurl
|
|
, flex, cracklib, db4, gettext, audit, libxcrypt
|
|
, nixosTests
|
|
, autoreconfHook269, pkg-config-unwrapped
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "linux-pam";
|
|
version = "1.6.1";
|
|
|
|
src = fetchurl {
|
|
url = "https://github.com/linux-pam/linux-pam/releases/download/v${version}/Linux-PAM-${version}.tar.xz";
|
|
hash = "sha256-+JI8dAFZBS1xnb/CovgZQtaN00/K9hxwagLJuA/u744=";
|
|
};
|
|
|
|
patches = [
|
|
./suid-wrapper-path.patch
|
|
];
|
|
|
|
# Case-insensitivity workaround for https://github.com/linux-pam/linux-pam/issues/569
|
|
postPatch = lib.optionalString (stdenv.buildPlatform.isDarwin && stdenv.buildPlatform != stdenv.hostPlatform) ''
|
|
rm CHANGELOG
|
|
touch ChangeLog
|
|
'';
|
|
|
|
outputs = [ "out" "doc" "man" /* "modules" */ ];
|
|
|
|
depsBuildBuild = [ buildPackages.stdenv.cc ];
|
|
# autoreconfHook269 is needed for `suid-wrapper-path.patch` above.
|
|
# pkg-config-unwrapped is needed for `AC_CHECK_LIB` and `AC_SEARCH_LIBS`
|
|
nativeBuildInputs = [ flex autoreconfHook269 pkg-config-unwrapped ]
|
|
++ lib.optional stdenv.buildPlatform.isDarwin gettext;
|
|
|
|
buildInputs = [ cracklib db4 libxcrypt ]
|
|
++ lib.optional stdenv.buildPlatform.isLinux audit;
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
configureFlags = [
|
|
"--includedir=${placeholder "out"}/include/security"
|
|
"--enable-sconfigdir=/etc/security"
|
|
# The module is deprecated. We re-enable it explicitly until NixOS
|
|
# module stops using it.
|
|
"--enable-lastlog"
|
|
];
|
|
|
|
installFlags = [
|
|
"SCONFIGDIR=${placeholder "out"}/etc/security"
|
|
];
|
|
|
|
doCheck = false; # fails
|
|
|
|
passthru.tests = {
|
|
inherit (nixosTests) pam-oath-login pam-u2f shadow sssd-ldap;
|
|
};
|
|
|
|
meta = with lib; {
|
|
homepage = "https://github.com/linux-pam/linux-pam";
|
|
description = "Pluggable Authentication Modules, a flexible mechanism for authenticating user";
|
|
platforms = platforms.linux;
|
|
license = licenses.bsd3;
|
|
};
|
|
}
|