mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-29 09:04:17 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
77 lines
2.0 KiB
Nix
77 lines
2.0 KiB
Nix
{ lib, stdenv, fetchurl
|
|
, buildPackages
|
|
, pkg-config
|
|
, zstd
|
|
, acl, attr, e2fsprogs, libuuid, lzo, udev, zlib
|
|
, runCommand, btrfs-progs
|
|
, gitUpdater
|
|
, udevSupport ? true
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "btrfs-progs";
|
|
version = "6.11";
|
|
|
|
src = fetchurl {
|
|
url = "mirror://kernel/linux/kernel/people/kdave/btrfs-progs/btrfs-progs-v${version}.tar.xz";
|
|
hash = "sha256-/5rpFSEwOpDYfhxL4jDwEh85xE3b5Swq6uJjxv7PoJk=";
|
|
};
|
|
|
|
nativeBuildInputs = [
|
|
pkg-config
|
|
] ++ [
|
|
(buildPackages.python3.withPackages (ps: with ps; [
|
|
sphinx
|
|
sphinx-rtd-theme
|
|
]))
|
|
];
|
|
|
|
buildInputs = [ acl attr e2fsprogs libuuid lzo udev zlib zstd ];
|
|
|
|
# gcc bug with -O1 on ARM with gcc 4.8
|
|
# This should be fine on all platforms so apply universally
|
|
postPatch = "sed -i s/-O1/-O2/ configure";
|
|
|
|
postInstall = ''
|
|
install -v -m 444 -D btrfs-completion $out/share/bash-completion/completions/btrfs
|
|
'';
|
|
|
|
configureFlags = [
|
|
# Built separately, see python3Packages.btrfsutil
|
|
"--disable-python"
|
|
] ++ lib.optionals stdenv.hostPlatform.isMusl [
|
|
"--disable-backtrace"
|
|
] ++ lib.optionals (!udevSupport) [
|
|
"--disable-libudev"
|
|
];
|
|
|
|
makeFlags = [ "udevruledir=$(out)/lib/udev/rules.d" ];
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
passthru.tests = {
|
|
simple-filesystem = runCommand "btrfs-progs-create-fs" {} ''
|
|
mkdir -p $out
|
|
truncate -s110M $out/disc
|
|
${btrfs-progs}/bin/mkfs.btrfs $out/disc | tee $out/success
|
|
${btrfs-progs}/bin/btrfs check $out/disc | tee $out/success
|
|
[ -e $out/success ]
|
|
'';
|
|
};
|
|
|
|
passthru.updateScript = gitUpdater {
|
|
# No nicer place to find latest release.
|
|
url = "https://github.com/kdave/btrfs-progs.git";
|
|
rev-prefix = "v";
|
|
};
|
|
|
|
meta = with lib; {
|
|
description = "Utilities for the btrfs filesystem";
|
|
homepage = "https://btrfs.readthedocs.io/en/latest/";
|
|
changelog = "https://github.com/kdave/btrfs-progs/raw/v${version}/CHANGES";
|
|
license = licenses.gpl2Only;
|
|
maintainers = with maintainers; [ raskin ];
|
|
platforms = platforms.linux;
|
|
};
|
|
}
|