mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-25 16:33:15 +00:00
36 lines
1.2 KiB
Nix
36 lines
1.2 KiB
Nix
{ lib, fetchgit, fetchzip }:
|
|
|
|
lib.makeOverridable (
|
|
# gitlab example
|
|
{ owner, repo, rev, protocol ? "https", domain ? "gitlab.com", name ? "source", group ? null
|
|
, fetchSubmodules ? false, leaveDotGit ? false
|
|
, deepClone ? false
|
|
, ... # For hash agility
|
|
} @ args:
|
|
|
|
let
|
|
slug = lib.concatStringsSep "/" ((lib.optional (group != null) group) ++ [ owner repo ]);
|
|
escapedSlug = lib.replaceStrings [ "." "/" ] [ "%2E" "%2F" ] slug;
|
|
escapedRev = lib.replaceStrings [ "+" "%" "/" ] [ "%2B" "%25" "%2F" ] rev;
|
|
passthruAttrs = removeAttrs args [ "protocol" "domain" "owner" "group" "repo" "rev" "fetchSubmodules" "leaveDotGit" "deepClone" ];
|
|
|
|
useFetchGit = fetchSubmodules || leaveDotGit || deepClone;
|
|
fetcher = if useFetchGit then fetchgit else fetchzip;
|
|
|
|
gitRepoUrl = "${protocol}://${domain}/${slug}.git";
|
|
|
|
fetcherArgs = (if useFetchGit then {
|
|
inherit rev deepClone fetchSubmodules leaveDotGit;
|
|
url = gitRepoUrl;
|
|
} else {
|
|
url = "${protocol}://${domain}/api/v4/projects/${escapedSlug}/repository/archive.tar.gz?sha=${escapedRev}";
|
|
|
|
passthru = {
|
|
inherit gitRepoUrl;
|
|
};
|
|
}) // passthruAttrs // { inherit name; };
|
|
in
|
|
|
|
fetcher fetcherArgs // { meta.homepage = "${protocol}://${domain}/${slug}/"; inherit rev; }
|
|
)
|