mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-09 14:33:22 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
98 lines
1.9 KiB
Nix
98 lines
1.9 KiB
Nix
{ lib
|
|
, stdenv
|
|
, fetchFromGitHub
|
|
, substituteAll
|
|
, meson
|
|
, ninja
|
|
, pkg-config
|
|
, buildPackages
|
|
, withIntrospection ? lib.meta.availableOn stdenv.hostPlatform gobject-introspection && stdenv.hostPlatform.emulatorAvailable buildPackages
|
|
, gobject-introspection
|
|
, gi-docgen
|
|
, python3
|
|
, glib
|
|
, libusb1
|
|
, json-glib
|
|
, vala
|
|
, hwdata
|
|
, umockdev
|
|
}:
|
|
|
|
let
|
|
pythonEnv = python3.pythonOnBuildForHost.withPackages (ps: with ps; [
|
|
setuptools
|
|
]);
|
|
in
|
|
stdenv.mkDerivation rec {
|
|
pname = "gusb";
|
|
version = "0.4.9";
|
|
|
|
outputs = [ "bin" "out" "dev" ]
|
|
++ lib.optionals withIntrospection [ "devdoc" ];
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "hughsie";
|
|
repo = "libgusb";
|
|
rev = "refs/tags/${version}";
|
|
hash = "sha256-piIPNLc3deToyQaajXFvM+CKh9ni8mb0P3kb+2RoJOs=";
|
|
};
|
|
|
|
patches = [
|
|
(substituteAll {
|
|
src = ./fix-python-path.patch;
|
|
python = "${pythonEnv}/bin/python3";
|
|
})
|
|
];
|
|
|
|
strictDeps = true;
|
|
|
|
depsBuildBuild = [
|
|
pkg-config
|
|
];
|
|
|
|
nativeBuildInputs = [
|
|
meson
|
|
ninja
|
|
pkg-config
|
|
] ++ lib.optionals withIntrospection [
|
|
gobject-introspection
|
|
gi-docgen
|
|
vala
|
|
];
|
|
|
|
# all required in gusb.pc
|
|
propagatedBuildInputs = [
|
|
glib
|
|
libusb1
|
|
json-glib
|
|
];
|
|
|
|
mesonFlags = [
|
|
(lib.mesonBool "docs" withIntrospection)
|
|
(lib.mesonBool "introspection" withIntrospection)
|
|
(lib.mesonBool "tests" doCheck)
|
|
(lib.mesonBool "vapi" withIntrospection)
|
|
(lib.mesonOption "usb_ids" "${hwdata}/share/hwdata/usb.ids")
|
|
];
|
|
|
|
checkInputs = [
|
|
umockdev
|
|
];
|
|
|
|
doCheck = false; # tests try to access USB
|
|
|
|
postFixup = ''
|
|
# Cannot be in postInstall, otherwise _multioutDocs hook in preFixup will move right back.
|
|
moveToOutput "share/doc" "$devdoc"
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "GLib libusb wrapper";
|
|
mainProgram = "gusbcmd";
|
|
homepage = "https://github.com/hughsie/libgusb";
|
|
license = licenses.lgpl21;
|
|
maintainers = [ maintainers.marcweber ];
|
|
platforms = platforms.unix;
|
|
};
|
|
}
|