mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-14 09:43:14 +00:00
92f7781f00
kernels: - longterm: 3.4.87 -> 3.4.88 - longterm: 3.10.37 -> 3.10.38 - stable: 3.13.10 -> 3.13.11 - stable: 3.14.1 -> 3.14.2 grsecurity: - test: 3.0-3.14.1-201404241722 -> 3.0-3.14.2-201404270907 NOTE: technically the 3.13 stable kernel is now EOL. However, it will become the long-term grsecurity stable kernel, and will have ongoing support from Canonical. Signed-off-by: Austin Seipp <aseipp@pobox.com>
113 lines
2.9 KiB
Nix
113 lines
2.9 KiB
Nix
{ stdenv, fetchurl, fetchgit, apparmor }:
|
|
|
|
let
|
|
|
|
makeTuxonicePatch = { version, kernelVersion, sha256,
|
|
url ? "http://tuxonice.nigelcunningham.com.au/downloads/all/tuxonice-for-linux-${kernelVersion}-${version}.patch.bz2" }:
|
|
{ name = "tuxonice-${kernelVersion}";
|
|
patch = stdenv.mkDerivation {
|
|
name = "tuxonice-${version}-for-${kernelVersion}.patch";
|
|
src = fetchurl {
|
|
inherit url sha256;
|
|
};
|
|
phases = [ "installPhase" ];
|
|
installPhase = ''
|
|
source $stdenv/setup
|
|
bunzip2 -c $src > $out
|
|
'';
|
|
};
|
|
};
|
|
|
|
grsecPatch = { grversion ? "3.0", kversion, revision, branch, sha256 }:
|
|
{ name = "grsecurity-${grversion}-${kversion}";
|
|
inherit grversion kversion revision;
|
|
patch = fetchurl {
|
|
url = "http://grsecurity.net/${branch}/grsecurity-${grversion}-${kversion}-${revision}.patch";
|
|
inherit sha256;
|
|
};
|
|
features.grsecurity = true;
|
|
# The grsec kernel patchset includes AppArmor patches
|
|
features.apparmor = true;
|
|
};
|
|
|
|
makeAppArmorPatch = {apparmor, version}:
|
|
stdenv.mkDerivation {
|
|
name = "apparmor-${version}.patch";
|
|
phases = ["installPhase"];
|
|
installPhase = ''
|
|
cat ${apparmor}/kernel-patches/${version}/* > $out
|
|
'';
|
|
};
|
|
|
|
in
|
|
|
|
rec {
|
|
|
|
apparmor_3_2 = rec {
|
|
version = "3.2";
|
|
name = "apparmor-${version}";
|
|
patch = makeAppArmorPatch { inherit apparmor version; };
|
|
features.apparmor = true;
|
|
};
|
|
|
|
apparmor_3_4 = rec {
|
|
version = "3.4";
|
|
name = "apparmor-${version}";
|
|
patch = makeAppArmorPatch { inherit apparmor version; };
|
|
features.apparmor = true;
|
|
};
|
|
|
|
no_xsave =
|
|
{ name = "no-xsave";
|
|
patch = ./no-xsave.patch;
|
|
features.noXsave = true;
|
|
};
|
|
|
|
mips_fpureg_emu =
|
|
{ name = "mips-fpureg-emulation";
|
|
patch = ./mips-fpureg-emulation.patch;
|
|
};
|
|
|
|
mips_fpu_sigill =
|
|
{ name = "mips-fpu-sigill";
|
|
patch = ./mips-fpu-sigill.patch;
|
|
};
|
|
|
|
mips_ext3_n32 =
|
|
{ name = "mips-ext3-n32";
|
|
patch = ./mips-ext3-n32.patch;
|
|
};
|
|
|
|
tuxonice_3_10 = makeTuxonicePatch {
|
|
version = "2013-11-07";
|
|
kernelVersion = "3.10.18";
|
|
sha256 = "00b1rqgd4yr206dxp4mcymr56ymbjcjfa4m82pxw73khj032qw3j";
|
|
};
|
|
|
|
grsecurity_stable = grsecPatch
|
|
{ kversion = "3.2.57";
|
|
revision = "201404241714";
|
|
branch = "stable";
|
|
sha256 = "0lrmmqllxas0dnaqswwbznh8cj5w9jw9df5dwzp16j71q8iqnv0c";
|
|
};
|
|
|
|
grsecurity_vserver = grsecPatch
|
|
{ kversion = "3.2.57";
|
|
revision = "vs2.3.2.16-201404241715";
|
|
branch = "vserver";
|
|
sha256 = "1839hnpxvg2hnkaslb5qbfdq4n5vcsndnkpw9mv0j6snc1wfx76s";
|
|
};
|
|
|
|
grsecurity_unstable = grsecPatch
|
|
{ kversion = "3.14.2";
|
|
revision = "201404270907";
|
|
branch = "test";
|
|
sha256 = "18hb6k873smhh65cxnmnd3qg9ysw5qlj7yb6m18aam6p77d6krsc";
|
|
};
|
|
|
|
grsec_fix_path =
|
|
{ name = "grsec-fix-path";
|
|
patch = ./grsec-path.patch;
|
|
};
|
|
}
|