mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-01 11:22:58 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
75 lines
1.9 KiB
Nix
75 lines
1.9 KiB
Nix
{ lib
|
|
, stdenv
|
|
, fetchFromGitHub
|
|
, pkg-config
|
|
, coreutils
|
|
, portaudio
|
|
, libbsd
|
|
, libpng
|
|
, libvorbis
|
|
, SDL2
|
|
, makeWrapper
|
|
, lua5_2
|
|
, glew
|
|
, openssl
|
|
, picotts
|
|
, alsa-utils
|
|
, espeak-classic
|
|
, sox
|
|
, libopus
|
|
, openscad
|
|
, libxcrypt
|
|
}:
|
|
|
|
stdenv.mkDerivation {
|
|
pname = "snis_launcher";
|
|
version = "unstable-2021-10-17";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "smcameron";
|
|
repo = "space-nerds-in-space";
|
|
rev = "e70d3c63e33c940feb53c8d818ce2d8ea2aadf00";
|
|
sha256 = "sha256-HVCb1iFn7GWNpedtFCgLyd0It8s4PEmUwDfb8ap1TDc=";
|
|
};
|
|
|
|
postPatch = ''
|
|
substituteInPlace Makefile \
|
|
--replace "OPUSARCHIVE=libopus.a" "OPUSARCHIVE=" \
|
|
--replace "-I./opus-1.3.1/include" "-I${libopus.dev}/include/opus"
|
|
substituteInPlace snis_launcher \
|
|
--replace "PREFIX=." "PREFIX=$out"
|
|
substituteInPlace snis_text_to_speech.sh \
|
|
--replace "pico2wave" "${sox}/bin/pico2wave" \
|
|
--replace "espeak" "${espeak-classic}/bin/espeak" \
|
|
--replace "play" "${sox}/bin/play" \
|
|
--replace "aplay" "${alsa-utils}/bin/aplay" \
|
|
--replace "/bin/rm" "${coreutils}/bin/rm"
|
|
'';
|
|
|
|
nativeBuildInputs = [ pkg-config openscad makeWrapper ];
|
|
buildInputs = [ coreutils portaudio libbsd libpng libvorbis SDL2 lua5_2 glew openssl picotts sox alsa-utils libopus libxcrypt ];
|
|
|
|
postBuild = ''
|
|
make models -j$NIX_BUILD_CORES
|
|
'';
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
mkdir -p $out
|
|
cp -R share $out/share
|
|
cp -R bin $out/bin
|
|
cp snis_launcher $out/bin/
|
|
# without this, snis_client crashes on Wayland
|
|
wrapProgram $out/bin/snis_client --set SDL_VIDEODRIVER x11
|
|
runHook postInstall
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Space Nerds In Space, a multi-player spaceship bridge simulator";
|
|
homepage = "https://smcameron.github.io/space-nerds-in-space/";
|
|
license = licenses.gpl2Plus;
|
|
maintainers = with maintainers; [ alyaeanyx ];
|
|
platforms = platforms.linux;
|
|
};
|
|
}
|