mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-04 03:53:56 +00:00
4f0dadbf38
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build a08b3a4d19.tar.gz \
--argstr baseRev b32a094368
result/bin/apply-formatting $NIXPKGS_PATH
92 lines
2.4 KiB
Nix
92 lines
2.4 KiB
Nix
{
|
|
config,
|
|
options,
|
|
lib,
|
|
...
|
|
}:
|
|
let
|
|
cfgSev = config.hardware.cpu.amd.sev;
|
|
cfgSevGuest = config.hardware.cpu.amd.sevGuest;
|
|
|
|
optionsFor = device: group: {
|
|
enable = lib.mkEnableOption "access to the AMD ${device} device";
|
|
user = lib.mkOption {
|
|
description = "Owner to assign to the ${device} device.";
|
|
type = lib.types.str;
|
|
default = "root";
|
|
};
|
|
group = lib.mkOption {
|
|
description = "Group to assign to the ${device} device.";
|
|
type = lib.types.str;
|
|
default = group;
|
|
};
|
|
mode = lib.mkOption {
|
|
description = "Mode to set for the ${device} device.";
|
|
type = lib.types.str;
|
|
default = "0660";
|
|
};
|
|
};
|
|
in
|
|
with lib;
|
|
{
|
|
options.hardware.cpu.amd.sev = optionsFor "SEV" "sev";
|
|
|
|
options.hardware.cpu.amd.sevGuest = optionsFor "SEV guest" "sev-guest";
|
|
|
|
config = lib.mkMerge [
|
|
# /dev/sev
|
|
(lib.mkIf cfgSev.enable {
|
|
assertions = [
|
|
{
|
|
assertion = lib.hasAttr cfgSev.user config.users.users;
|
|
message = "Given user does not exist";
|
|
}
|
|
{
|
|
assertion =
|
|
(cfgSev.group == options.hardware.cpu.amd.sev.group.default)
|
|
|| (lib.hasAttr cfgSev.group config.users.groups);
|
|
message = "Given group does not exist";
|
|
}
|
|
];
|
|
|
|
boot.extraModprobeConfig = ''
|
|
options kvm_amd sev=1
|
|
'';
|
|
|
|
users.groups = lib.optionalAttrs (cfgSev.group == options.hardware.cpu.amd.sev.group.default) {
|
|
"${cfgSev.group}" = { };
|
|
};
|
|
|
|
services.udev.extraRules = with cfgSev; ''
|
|
KERNEL=="sev", OWNER="${user}", GROUP="${group}", MODE="${mode}"
|
|
'';
|
|
})
|
|
|
|
# /dev/sev-guest
|
|
(lib.mkIf cfgSevGuest.enable {
|
|
assertions = [
|
|
{
|
|
assertion = lib.hasAttr cfgSevGuest.user config.users.users;
|
|
message = "Given user does not exist";
|
|
}
|
|
{
|
|
assertion =
|
|
(cfgSevGuest.group == options.hardware.cpu.amd.sevGuest.group.default)
|
|
|| (lib.hasAttr cfgSevGuest.group config.users.groups);
|
|
message = "Given group does not exist";
|
|
}
|
|
];
|
|
|
|
users.groups =
|
|
lib.optionalAttrs (cfgSevGuest.group == options.hardware.cpu.amd.sevGuest.group.default)
|
|
{
|
|
"${cfgSevGuest.group}" = { };
|
|
};
|
|
|
|
services.udev.extraRules = with cfgSevGuest; ''
|
|
KERNEL=="sev-guest", OWNER="${user}", GROUP="${group}", MODE="${mode}"
|
|
'';
|
|
})
|
|
];
|
|
}
|