mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-02-16 00:54:40 +00:00
e0464e4788
In preparation for the deprecation of `stdenv.isX`. These shorthands are not conducive to cross-compilation because they hide the platforms. Darwin might get cross-compilation for which the continued usage of `stdenv.isDarwin` will get in the way One example of why this is bad and especially affects compiler packages https://www.github.com/NixOS/nixpkgs/pull/343059 There are too many files to go through manually but a treewide should get users thinking when they see a `hostPlatform.isX` in a place where it doesn't make sense. ``` fd --type f "\.nix" | xargs sd --fixed-strings "stdenv.is" "stdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenv'.is" "stdenv'.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "clangStdenv.is" "clangStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "gccStdenv.is" "gccStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenvNoCC.is" "stdenvNoCC.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "inherit (stdenv) is" "inherit (stdenv.hostPlatform) is" fd --type f "\.nix" | xargs sd --fixed-strings "buildStdenv.is" "buildStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "effectiveStdenv.is" "effectiveStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "originalStdenv.is" "originalStdenv.hostPlatform.is" ```
57 lines
1.6 KiB
Nix
57 lines
1.6 KiB
Nix
{
|
|
blasfeo,
|
|
cmake,
|
|
fetchFromGitHub,
|
|
lib,
|
|
llvmPackages,
|
|
python3Packages,
|
|
pythonSupport ? false,
|
|
stdenv,
|
|
}:
|
|
|
|
stdenv.mkDerivation (finalAttrs: {
|
|
pname = "fatrop";
|
|
version = "0.0.1";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "meco-group";
|
|
repo = "fatrop";
|
|
rev = "v${finalAttrs.version}";
|
|
hash = "sha256-c4qYh8RutRsMIx3m0oxXy73fnLTBGVZ1QjFcLEJ413Y=";
|
|
};
|
|
|
|
postPatch = lib.optionalString pythonSupport ''
|
|
# avoid submodule
|
|
rmdir external/pybind11
|
|
ln -s ${python3Packages.pybind11.src} external/pybind11
|
|
|
|
# install python module
|
|
echo "" >> fatropy/CMakeLists.txt
|
|
echo "install(DIRECTORY fatropy DESTINATION ${python3Packages.python.sitePackages})" >> fatropy/CMakeLists.txt
|
|
echo "install(TARGETS _fatropy DESTINATION ${python3Packages.python.sitePackages}/fatropy)" >> fatropy/CMakeLists.txt
|
|
'';
|
|
|
|
nativeBuildInputs = [ cmake ];
|
|
buildInputs =
|
|
[ blasfeo ]
|
|
++ lib.optionals pythonSupport [ python3Packages.pybind11 ]
|
|
++ lib.optionals stdenv.hostPlatform.isDarwin [ llvmPackages.openmp ];
|
|
|
|
cmakeFlags = [
|
|
(lib.cmakeBool "BUILD_DOCS" true)
|
|
(lib.cmakeBool "ENABLE_MULTITHREADING" true)
|
|
(lib.cmakeBool "BUILD_WITH_BLASFEO" false)
|
|
(lib.cmakeBool "WITH_PYTHON" pythonSupport)
|
|
(lib.cmakeBool "WITH_SPECTOOL" false) # this depends on casadi
|
|
];
|
|
|
|
doCheck = true;
|
|
|
|
meta = {
|
|
description = "nonlinear optimal control problem solver that aims to be fast, support a broad class of optimal control problems and achieve a high numerical robustness";
|
|
homepage = "https://github.com/meco-group/fatrop";
|
|
license = lib.licenses.lgpl3Only;
|
|
maintainers = with lib.maintainers; [ nim65s ];
|
|
};
|
|
})
|