mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-11 16:23:26 +00:00
72 lines
2.3 KiB
Nix
72 lines
2.3 KiB
Nix
{ lib
|
||
, gitSupport ? true
|
||
, stdenv
|
||
, fetchFromGitHub
|
||
, rustPlatform
|
||
, cmake
|
||
, pandoc
|
||
, pkg-config
|
||
, zlib
|
||
, darwin
|
||
, libiconv
|
||
, installShellFiles
|
||
# once eza upstream gets support for setting up a compatibility symlink for exa, we should change
|
||
# the handling here from postInstall to passing the required argument to the builder.
|
||
, exaAlias ? true
|
||
}:
|
||
|
||
rustPlatform.buildRustPackage rec {
|
||
pname = "eza";
|
||
version = "0.20.2";
|
||
|
||
src = fetchFromGitHub {
|
||
owner = "eza-community";
|
||
repo = "eza";
|
||
rev = "v${version}";
|
||
hash = "sha256-lit0v9emrAYkHWpCP1Z35UdrKdMiDh2HWeQg4WfxJIo=";
|
||
};
|
||
|
||
cargoHash = "sha256-TwUbEeka20K9C8TvJH/Hiv8qp66TjAkcyMG7K2JuagQ=";
|
||
|
||
nativeBuildInputs = [ cmake pkg-config installShellFiles pandoc ];
|
||
buildInputs = [ zlib ]
|
||
++ lib.optionals stdenv.hostPlatform.isDarwin [ libiconv darwin.apple_sdk.frameworks.Security ];
|
||
|
||
buildNoDefaultFeatures = true;
|
||
buildFeatures = lib.optional gitSupport "git";
|
||
|
||
outputs = [ "out" "man" ];
|
||
|
||
postInstall = ''
|
||
for page in eza.1 eza_colors.5 eza_colors-explanation.5; do
|
||
sed "s/\$version/v${version}/g" "man/$page.md" |
|
||
pandoc --standalone -f markdown -t man >"man/$page"
|
||
done
|
||
installManPage man/eza.1 man/eza_colors.5 man/eza_colors-explanation.5
|
||
installShellCompletion \
|
||
--bash completions/bash/eza \
|
||
--fish completions/fish/eza.fish \
|
||
--zsh completions/zsh/_eza
|
||
'' + lib.optionalString exaAlias ''
|
||
ln -s eza $out/bin/exa
|
||
'';
|
||
|
||
meta = with lib; {
|
||
description = "Modern, maintained replacement for ls";
|
||
longDescription = ''
|
||
eza is a modern replacement for ls. It uses colours for information by
|
||
default, helping you distinguish between many types of files, such as
|
||
whether you are the owner, or in the owning group. It also has extra
|
||
features not present in the original ls, such as viewing the Git status
|
||
for a directory, or recursing into directories with a tree view. eza is
|
||
written in Rust, so it’s small, fast, and portable.
|
||
'';
|
||
homepage = "https://github.com/eza-community/eza";
|
||
changelog = "https://github.com/eza-community/eza/releases/tag/v${version}";
|
||
license = licenses.eupl12;
|
||
mainProgram = "eza";
|
||
maintainers = with maintainers; [ cafkafk _9glenda ];
|
||
platforms = platforms.unix ++ platforms.windows;
|
||
};
|
||
}
|