mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-03 19:43:30 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
54 lines
1.7 KiB
Nix
54 lines
1.7 KiB
Nix
{ lib
|
|
, stdenv
|
|
, rustPlatform
|
|
, fetchFromGitHub
|
|
, asciidoctor
|
|
, installShellFiles
|
|
, makeWrapper
|
|
, ripgrep
|
|
}:
|
|
|
|
rustPlatform.buildRustPackage rec {
|
|
pname = "repgrep";
|
|
version = "0.15.0";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "acheronfail";
|
|
repo = "repgrep";
|
|
rev = version;
|
|
hash = "sha256-6ba7EJUts0Ni9EA3ENlK+a2FaPo7JohtCyqwR9DdL1E=";
|
|
};
|
|
|
|
cargoHash = "sha256-XEjKTZ3qaiLWbm2wF+V97u9tGXDq/oTm249ubUE9n94=";
|
|
|
|
nativeBuildInputs = [
|
|
asciidoctor
|
|
installShellFiles
|
|
makeWrapper
|
|
];
|
|
|
|
postInstall = ''
|
|
wrapProgram $out/bin/rgr \
|
|
--prefix PATH : ${lib.makeBinPath [ ripgrep ]}
|
|
|
|
pushd "$(dirname "$(find -path '**/repgrep-stamp' | head -n 1)")"
|
|
installManPage rgr.1
|
|
popd
|
|
'' + lib.optionalString (stdenv.hostPlatform.canExecute stdenv.buildPlatform) ''
|
|
# As it can be seen here: https://github.com/acheronfail/repgrep/blob/0.15.0/.github/workflows/release.yml#L206, the completions are just the same as ripgrep
|
|
installShellCompletion --cmd rgr \
|
|
--bash <(${lib.getExe ripgrep} --generate complete-bash | sed 's/-c rg/-c rgr/') \
|
|
--zsh <(${lib.getExe ripgrep} --generate complete-zsh | sed 's/-c rg/-c rgr/') \
|
|
--fish <(${lib.getExe ripgrep} --generate complete-fish | sed 's/-c rg/-c rgr/')
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Interactive replacer for ripgrep that makes it easy to find and replace across files on the command line";
|
|
homepage = "https://github.com/acheronfail/repgrep";
|
|
changelog = "https://github.com/acheronfail/repgrep/blob/${src.rev}/CHANGELOG.md";
|
|
license = with licenses; [ mit asl20 unlicense ];
|
|
maintainers = with maintainers; [ figsoda ];
|
|
mainProgram = "rgr";
|
|
};
|
|
}
|