mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-02 11:53:27 +00:00
9833d56c24
Done with the help of https://github.com/Mindavi/nixpkgs-mark-broken Tool is still WIP but this is one of the first results. I manually audited the results and removed some results that were not valid. Note that some of these packages maybe should have more constrained platforms set instead of broken set, but I think not being perfectly correct is better than just keep trying to build all these things and never succeeding. Some observations: - Some darwin builds require XCode tools - aarch64-linux builds sometimes suffer from using gcc9 - gcc9 is getting older and misses some new libraries/features - Sometimes tools try to do system detection or expect some explicit settings for platforms that are not x86_64-linux
70 lines
1.3 KiB
Nix
70 lines
1.3 KiB
Nix
{ lib
|
|
, stdenv
|
|
, fetchFromGitHub
|
|
, alsa-lib
|
|
, cmake
|
|
, doxygen
|
|
, libX11
|
|
, libXcursor
|
|
, libXext
|
|
, libXft
|
|
, libXinerama
|
|
, libXrandr
|
|
, pkg-config
|
|
, zlib
|
|
, AGL
|
|
, Cocoa
|
|
, Foundation
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "libopenshot-audio";
|
|
version = "0.2.2";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "OpenShot";
|
|
repo = "libopenshot-audio";
|
|
rev = "v${version}";
|
|
sha256 = "sha256-XtwTZsj/L/sw/28E7Qr5UyghGlBFFXvbmZLGXBB8vg0=";
|
|
};
|
|
|
|
nativeBuildInputs = [
|
|
cmake
|
|
doxygen
|
|
pkg-config
|
|
];
|
|
|
|
buildInputs = lib.optionals stdenv.isLinux [
|
|
alsa-lib
|
|
] ++ (if stdenv.isDarwin then [
|
|
AGL
|
|
Cocoa
|
|
Foundation
|
|
zlib
|
|
] else [
|
|
libX11
|
|
libXcursor
|
|
libXext
|
|
libXft
|
|
libXinerama
|
|
libXrandr
|
|
]);
|
|
|
|
doCheck = false;
|
|
|
|
meta = with lib; {
|
|
homepage = "http://openshot.org/";
|
|
description = "High-quality sound editing library";
|
|
longDescription = ''
|
|
OpenShot Audio Library (libopenshot-audio) is a program that allows the
|
|
high-quality editing and playback of audio, and is based on the amazing
|
|
JUCE library.
|
|
'';
|
|
license = with licenses; gpl3Plus;
|
|
maintainers = with maintainers; [ AndersonTorres ];
|
|
platforms = with platforms; unix;
|
|
# never built on aarch64-darwin since first introduction in nixpkgs
|
|
broken = stdenv.isDarwin && stdenv.isAarch64;
|
|
};
|
|
}
|