mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-13 09:13:17 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
118 lines
3.0 KiB
Nix
118 lines
3.0 KiB
Nix
{ lib
|
|
, stdenv
|
|
, yarn
|
|
, fetchYarnDeps
|
|
, fixup-yarn-lock
|
|
, nodejs
|
|
, electron
|
|
, fetchFromGitHub
|
|
, nix-update-script
|
|
, makeWrapper
|
|
, makeDesktopItem
|
|
, copyDesktopItems
|
|
}:
|
|
|
|
stdenv.mkDerivation (finalAttrs: {
|
|
pname = "r2modman";
|
|
version = "3.1.50";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "ebkr";
|
|
repo = "r2modmanPlus";
|
|
rev = "v${finalAttrs.version}";
|
|
hash = "sha256-WmF7tH5PiaggyvP/klWwNgaLKVhIoApxDtwwLpug52A=";
|
|
};
|
|
|
|
offlineCache = fetchYarnDeps {
|
|
yarnLock = "${finalAttrs.src}/yarn.lock";
|
|
hash = "sha256-ntXZ4gRXRqiPQxdwXDsLxGdBqUV5eboy9ntTlJsz9FA=";
|
|
};
|
|
|
|
patches = [
|
|
# Make it possible to launch Steam games from r2modman.
|
|
./steam-launch-fix.patch
|
|
];
|
|
|
|
nativeBuildInputs = [
|
|
yarn
|
|
fixup-yarn-lock
|
|
nodejs
|
|
makeWrapper
|
|
copyDesktopItems
|
|
];
|
|
|
|
configurePhase = ''
|
|
runHook preConfigure
|
|
|
|
# Workaround for webpack bug
|
|
# https://github.com/webpack/webpack/issues/14532
|
|
export NODE_OPTIONS="--openssl-legacy-provider"
|
|
export HOME=$(mktemp -d)
|
|
yarn config --offline set yarn-offline-mirror $offlineCache
|
|
fixup-yarn-lock yarn.lock
|
|
yarn install --offline --frozen-lockfile --ignore-platform --ignore-scripts --no-progress --non-interactive
|
|
patchShebangs node_modules/
|
|
|
|
runHook postConfigure
|
|
'';
|
|
|
|
buildPhase = ''
|
|
runHook preBuild
|
|
|
|
yarn --offline quasar build --mode electron --skip-pkg
|
|
|
|
# Remove dev dependencies.
|
|
yarn install --production --offline --frozen-lockfile --ignore-platform --ignore-scripts --no-progress --non-interactive
|
|
|
|
runHook postBuild
|
|
'';
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
|
|
mkdir -p $out/share/r2modman
|
|
cp -r dist/electron/UnPackaged/. node_modules $out/share/r2modman
|
|
|
|
(
|
|
cd public/icons
|
|
for img in *png; do
|
|
dimensions=''${img#favicon-}
|
|
dimensions=''${dimensions%.png}
|
|
mkdir -p $out/share/icons/hicolor/$dimensions/apps
|
|
cp $img $out/share/icons/hicolor/$dimensions/apps/r2modman.png
|
|
done
|
|
)
|
|
|
|
makeWrapper '${lib.getExe electron}' "$out/bin/r2modman" \
|
|
--inherit-argv0 \
|
|
--add-flags "$out/share/r2modman" \
|
|
--add-flags "\''${NIXOS_OZONE_WL:+\''${WAYLAND_DISPLAY:+--ozone-platform-hint=auto --enable-features=WaylandWindowDecorations}}"
|
|
|
|
runHook postInstall
|
|
'';
|
|
|
|
desktopItems = [
|
|
(makeDesktopItem {
|
|
name = "r2modman";
|
|
exec = "r2modman";
|
|
icon = "r2modman";
|
|
desktopName = "r2modman";
|
|
comment = finalAttrs.meta.description;
|
|
categories = [ "Game" ];
|
|
keywords = [ "launcher" "mod manager" "thunderstore" ];
|
|
})
|
|
];
|
|
|
|
passthru.updateScript = nix-update-script { };
|
|
|
|
meta = {
|
|
changelog = "https://github.com/ebkr/r2modmanPlus/releases/tag/v${finalAttrs.version}";
|
|
description = "Unofficial Thunderstore mod manager";
|
|
homepage = "https://github.com/ebkr/r2modmanPlus";
|
|
license = lib.licenses.mit;
|
|
mainProgram = "r2modman";
|
|
maintainers = with lib.maintainers; [ aidalgol huantian ];
|
|
inherit (electron.meta) platforms;
|
|
};
|
|
})
|