mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-10 06:55:10 +00:00
4f0dadbf38
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build a08b3a4d19.tar.gz \
--argstr baseRev b32a094368
result/bin/apply-formatting $NIXPKGS_PATH
108 lines
3.1 KiB
Nix
108 lines
3.1 KiB
Nix
{
|
|
lib,
|
|
stdenv,
|
|
fetchFromGitHub,
|
|
lua,
|
|
jemalloc,
|
|
pkg-config,
|
|
tcl,
|
|
which,
|
|
ps,
|
|
getconf,
|
|
withSystemd ? lib.meta.availableOn stdenv.hostPlatform systemd,
|
|
systemd,
|
|
# dependency ordering is broken at the moment when building with openssl
|
|
tlsSupport ? !stdenv.hostPlatform.isStatic,
|
|
openssl,
|
|
|
|
# Using system jemalloc fixes cross-compilation and various setups.
|
|
# However the experimental 'active defragmentation' feature of valkey requires
|
|
# their custom patched version of jemalloc.
|
|
useSystemJemalloc ? true,
|
|
}:
|
|
|
|
stdenv.mkDerivation (finalAttrs: {
|
|
pname = "valkey";
|
|
version = "8.0.1";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "valkey-io";
|
|
repo = "valkey";
|
|
rev = finalAttrs.version;
|
|
hash = "sha256-WB0blQLxQOTkK8UGsH6WISZAisUAtGIDfjoc4RnPSew=";
|
|
};
|
|
|
|
patches = lib.optional useSystemJemalloc ./use_system_jemalloc.patch;
|
|
|
|
nativeBuildInputs = [ pkg-config ];
|
|
|
|
buildInputs =
|
|
[ lua ]
|
|
++ lib.optional useSystemJemalloc jemalloc
|
|
++ lib.optional withSystemd systemd
|
|
++ lib.optional tlsSupport openssl;
|
|
|
|
strictDeps = true;
|
|
|
|
preBuild = lib.optionalString stdenv.hostPlatform.isDarwin ''
|
|
substituteInPlace src/Makefile --replace-fail "-flto" ""
|
|
'';
|
|
|
|
# More cross-compiling fixes.
|
|
makeFlags =
|
|
[ "PREFIX=${placeholder "out"}" ]
|
|
++ lib.optionals (stdenv.buildPlatform != stdenv.hostPlatform) [
|
|
"AR=${stdenv.cc.targetPrefix}ar"
|
|
"RANLIB=${stdenv.cc.targetPrefix}ranlib"
|
|
]
|
|
++ lib.optionals withSystemd [ "USE_SYSTEMD=yes" ]
|
|
++ lib.optionals tlsSupport [ "BUILD_TLS=yes" ];
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
hardeningEnable = lib.optionals (!stdenv.hostPlatform.isDarwin) [ "pie" ];
|
|
|
|
env.NIX_CFLAGS_COMPILE = toString (lib.optionals stdenv.cc.isClang [ "-std=c11" ]);
|
|
|
|
# darwin currently lacks a pure `pgrep` which is extensively used here
|
|
doCheck = !stdenv.hostPlatform.isDarwin;
|
|
nativeCheckInputs = [
|
|
which
|
|
tcl
|
|
ps
|
|
] ++ lib.optionals stdenv.hostPlatform.isStatic [ getconf ];
|
|
checkPhase = ''
|
|
runHook preCheck
|
|
|
|
# disable test "Connect multiple replicas at the same time": even
|
|
# upstream find this test too timing-sensitive
|
|
substituteInPlace tests/integration/replication.tcl \
|
|
--replace-fail 'foreach mdl {no yes} dualchannel {no yes}' 'foreach mdl {} dualchannel {}'
|
|
|
|
substituteInPlace tests/support/server.tcl \
|
|
--replace-fail 'exec /usr/bin/env' 'exec env'
|
|
|
|
sed -i '/^proc wait_load_handlers_disconnected/{n ; s/wait_for_condition 50 100/wait_for_condition 50 500/; }' \
|
|
tests/support/util.tcl
|
|
|
|
./runtest \
|
|
--no-latency \
|
|
--timeout 2000 \
|
|
--clients $NIX_BUILD_CORES \
|
|
--tags -leaks \
|
|
--skipunit integration/failover # flaky and slow
|
|
|
|
runHook postCheck
|
|
'';
|
|
|
|
meta = with lib; {
|
|
homepage = "https://valkey.io/";
|
|
description = "High-performance data structure server that primarily serves key/value workloads";
|
|
license = licenses.bsd3;
|
|
platforms = platforms.all;
|
|
maintainers = with maintainers; [ rucadi ];
|
|
changelog = "https://github.com/valkey-io/valkey/releases/tag/${finalAttrs.version}";
|
|
mainProgram = "valkey-cli";
|
|
};
|
|
})
|