mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-06 13:03:34 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
69 lines
1.9 KiB
Nix
69 lines
1.9 KiB
Nix
{ lib
|
|
, stdenv
|
|
, fetchurl
|
|
, autoPatchelfHook
|
|
, gcc-unwrapped
|
|
, zlib
|
|
}:
|
|
|
|
let
|
|
system = stdenv.hostPlatform.system;
|
|
|
|
platform = {
|
|
x86_64-linux = "linux-amd64";
|
|
aarch64-linux = "linux-aarch64";
|
|
x86_64-darwin = "macos-amd64";
|
|
aarch64-darwin = "macos-aarch64";
|
|
}.${system} or (throw "Unsupported system: ${system}");
|
|
|
|
# TODO: It'd be nice to write an update script that would update all of these
|
|
# hashes together.
|
|
packageHash = {
|
|
x86_64-linux = "sha256-gYHIfvgofT9tKYCchZoRYvioLCtp2wfaOtuVWxTyujM=";
|
|
aarch64-linux = "sha256-zW+aeUc67pa6mQQkfazShHKAvGeucswLK1eRCxzXOJM=";
|
|
x86_64-darwin = "sha256-ph+SrrxOIyG9rRS098duhvDFiNGuh0o2uemm++J+zKw=";
|
|
aarch64-darwin = "sha256-eOpRaivRhk841/TCxC4ygw27UrPkqQCMH2mme2qo8V8=";
|
|
}.${system} or (throw "Unsupported system: ${system}");
|
|
|
|
in stdenv.mkDerivation rec {
|
|
pname = "fermyon-spin";
|
|
version = "2.5.1";
|
|
|
|
# Use fetchurl rather than fetchzip as these tarballs are built by the project
|
|
# and not by GitHub (and thus are stable) - this simplifies the update script
|
|
# by allowing it to use the output of `nix store prefetch-file`.
|
|
src = fetchurl {
|
|
url = "https://github.com/fermyon/spin/releases/download/v${version}/spin-v${version}-${platform}.tar.gz";
|
|
hash = packageHash;
|
|
};
|
|
|
|
sourceRoot = ".";
|
|
|
|
nativeBuildInputs = lib.optionals stdenv.hostPlatform.isLinux [
|
|
autoPatchelfHook
|
|
];
|
|
|
|
buildInputs = [
|
|
gcc-unwrapped.lib
|
|
zlib
|
|
];
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
|
|
mkdir -p $out/bin
|
|
cp ./spin $out/bin
|
|
|
|
runHook postInstall
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Framework for building, deploying, and running fast, secure, and composable cloud microservices with WebAssembly";
|
|
homepage = "https://github.com/fermyon/spin";
|
|
license = with licenses; [ asl20 ];
|
|
mainProgram = "spin";
|
|
maintainers = with maintainers; [ mglolenstine ];
|
|
platforms = platforms.linux ++ platforms.darwin;
|
|
};
|
|
}
|