mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-24 07:53:19 +00:00
6afb255d97
these changes were generated with nixq 0.0.2, by running nixq ">> lib.mdDoc[remove] Argument[keep]" --batchmode nixos/**.nix nixq ">> mdDoc[remove] Argument[keep]" --batchmode nixos/**.nix nixq ">> Inherit >> mdDoc[remove]" --batchmode nixos/**.nix two mentions of the mdDoc function remain in nixos/, both of which are inside of comments. Since lib.mdDoc is already defined as just id, this commit is a no-op as far as Nix (and the built manual) is concerned.
83 lines
2.2 KiB
Nix
83 lines
2.2 KiB
Nix
{ config, pkgs, lib, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
cfg = config.services.plikd;
|
|
|
|
format = pkgs.formats.toml {};
|
|
plikdCfg = format.generate "plikd.cfg" cfg.settings;
|
|
in
|
|
{
|
|
options = {
|
|
services.plikd = {
|
|
enable = mkEnableOption "plikd, a temporary file upload system";
|
|
|
|
openFirewall = mkOption {
|
|
type = types.bool;
|
|
default = false;
|
|
description = "Open ports in the firewall for the plikd.";
|
|
};
|
|
|
|
settings = mkOption {
|
|
type = format.type;
|
|
default = {};
|
|
description = ''
|
|
Configuration for plikd, see <https://github.com/root-gg/plik/blob/master/server/plikd.cfg>
|
|
for supported values.
|
|
'';
|
|
};
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
services.plikd.settings = mapAttrs (name: mkDefault) {
|
|
ListenPort = 8080;
|
|
ListenAddress = "localhost";
|
|
DataBackend = "file";
|
|
DataBackendConfig = {
|
|
Directory = "/var/lib/plikd";
|
|
};
|
|
MetadataBackendConfig = {
|
|
Driver = "sqlite3";
|
|
ConnectionString = "/var/lib/plikd/plik.db";
|
|
};
|
|
};
|
|
|
|
systemd.services.plikd = {
|
|
description = "Plikd file sharing server";
|
|
after = [ "network.target" ];
|
|
wantedBy = [ "multi-user.target" ];
|
|
serviceConfig = {
|
|
Type = "simple";
|
|
ExecStart = "${pkgs.plikd}/bin/plikd --config ${plikdCfg}";
|
|
Restart = "on-failure";
|
|
StateDirectory = "plikd";
|
|
LogsDirectory = "plikd";
|
|
DynamicUser = true;
|
|
|
|
# Basic hardening
|
|
NoNewPrivileges = "yes";
|
|
PrivateTmp = "yes";
|
|
PrivateDevices = "yes";
|
|
DevicePolicy = "closed";
|
|
ProtectSystem = "strict";
|
|
ProtectHome = "read-only";
|
|
ProtectControlGroups = "yes";
|
|
ProtectKernelModules = "yes";
|
|
ProtectKernelTunables = "yes";
|
|
RestrictAddressFamilies = "AF_UNIX AF_INET AF_INET6 AF_NETLINK";
|
|
RestrictNamespaces = "yes";
|
|
RestrictRealtime = "yes";
|
|
RestrictSUIDSGID = "yes";
|
|
MemoryDenyWriteExecute = "yes";
|
|
LockPersonality = "yes";
|
|
};
|
|
};
|
|
|
|
networking.firewall = mkIf cfg.openFirewall {
|
|
allowedTCPPorts = [ cfg.settings.ListenPort ];
|
|
};
|
|
};
|
|
}
|