mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-27 08:04:14 +00:00
4f0dadbf38
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build a08b3a4d19.tar.gz \
--argstr baseRev b32a094368
result/bin/apply-formatting $NIXPKGS_PATH
41 lines
1013 B
Nix
41 lines
1013 B
Nix
# Evaluate `release.nix' like Hydra would. Too bad nix-instantiate can't to do this.
|
||
|
||
let
|
||
inherit (import ../../lib) isDerivation mapAttrs;
|
||
|
||
trace = if builtins.getEnv "VERBOSE" == "1" then builtins.trace else (x: y: y);
|
||
|
||
rel = removeAttrs (import ../../pkgs/top-level/release.nix { }) [
|
||
"tarball"
|
||
"unstable"
|
||
];
|
||
|
||
# Add the ‘recurseForDerivations’ attribute to ensure that
|
||
# nix-instantiate recurses into nested attribute sets.
|
||
recurse =
|
||
path: attrs:
|
||
if (builtins.tryEval attrs).success then
|
||
if isDerivation attrs then
|
||
if (builtins.tryEval attrs.drvPath).success then
|
||
{ inherit (attrs) name drvPath; }
|
||
else
|
||
{ failed = true; }
|
||
else if attrs == null then
|
||
{ }
|
||
else
|
||
{
|
||
recurseForDerivations = true;
|
||
}
|
||
// mapAttrs (
|
||
n: v:
|
||
let
|
||
path' = path ++ [ n ];
|
||
in
|
||
trace path' (recurse path' v)
|
||
) attrs
|
||
else
|
||
{ };
|
||
|
||
in
|
||
recurse [ ] rel
|