mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-24 06:33:42 +00:00
b087618ac0
As @oxij points out in [1], this breakage is especially serious because
it changes the contents of built environments without a corresonding
change in their hashes. Also, the revert is easier than I thought.
This reverts commit 3cb745d5a6.
[1]: https://github.com/NixOS/nixpkgs/pull/27427#issuecomment-317293040
254 lines
8.9 KiB
Nix
254 lines
8.9 KiB
Nix
{ stdenv, lib, fetchurl, cpio, pkgconfig, file, which, unzip, zip, cups, freetype
|
|
, alsaLib, bootjdk, cacert, perl, liberation_ttf, fontconfig, zlib, lndir
|
|
, libX11, libICE, libXrender, libXext, libXt, libXtst, libXi, libXinerama, libXcursor
|
|
, libjpeg, giflib
|
|
, setJavaClassPath
|
|
, minimal ? false
|
|
, enableInfinality ? true # font rendering patch
|
|
, enableGnome2 ? true, gtk2, gnome_vfs, glib, GConf
|
|
}:
|
|
|
|
let
|
|
|
|
/**
|
|
* The JRE libraries are in directories that depend on the CPU.
|
|
*/
|
|
architecture =
|
|
if stdenv.system == "i686-linux" then
|
|
"i386"
|
|
else if stdenv.system == "x86_64-linux" then
|
|
"amd64"
|
|
else
|
|
throw "openjdk requires i686-linux or x86_64 linux";
|
|
|
|
update = "141";
|
|
build = "15";
|
|
baseurl = "http://hg.openjdk.java.net/jdk8u/jdk8u";
|
|
repover = "jdk8u${update}-b${build}";
|
|
paxflags = if stdenv.isi686 then "msp" else "m";
|
|
jdk8 = fetchurl {
|
|
url = "${baseurl}/archive/${repover}.tar.gz";
|
|
sha256 = "0b2nf1x2wcjn0ijyxhnrhcap4vq43sbblh5kf0qcqmx83cs3z6yh";
|
|
};
|
|
langtools = fetchurl {
|
|
url = "${baseurl}/langtools/archive/${repover}.tar.gz";
|
|
sha256 = "1mirjjywv7mnirrxj5sx3zg6j2864vjvphkn9mxx1pad49by7157";
|
|
};
|
|
hotspot = fetchurl {
|
|
url = "${baseurl}/hotspot/archive/${repover}.tar.gz";
|
|
sha256 = "0hhvsrclx58i7ns2v7la2wncnndblppwjncniwcvhnhgl5zhpp31";
|
|
};
|
|
corba = fetchurl {
|
|
url = "${baseurl}/corba/archive/${repover}.tar.gz";
|
|
sha256 = "1brr72rlpaz70ihymdyp808vw433cr8b11l5qdc76aic2ywbwjyp";
|
|
};
|
|
jdk = fetchurl {
|
|
url = "${baseurl}/jdk/archive/${repover}.tar.gz";
|
|
sha256 = "1d4q531jswzk00kdskzfkgr0f4qmxpc7pg9w8p1gq84yz93wz11k";
|
|
};
|
|
jaxws = fetchurl {
|
|
url = "${baseurl}/jaxws/archive/${repover}.tar.gz";
|
|
sha256 = "0haw5095p45w33m8pafnp5r5j2lif8c1271chad5sp4gbbk40ai4";
|
|
};
|
|
jaxp = fetchurl {
|
|
url = "${baseurl}/jaxp/archive/${repover}.tar.gz";
|
|
sha256 = "0pm2cccy31d9rnkgc2hcxbpjjhf4wbayx18qn736nncvwcwa76bj";
|
|
};
|
|
nashorn = fetchurl {
|
|
url = "${baseurl}/nashorn/archive/${repover}.tar.gz";
|
|
sha256 = "1g05vfggjjg51dki28zby27pnd4z1b23fv9kyc3hdmc4bcj306x0";
|
|
};
|
|
openjdk8 = stdenv.mkDerivation {
|
|
name = "openjdk-8u${update}b${build}";
|
|
|
|
srcs = [ jdk8 langtools hotspot corba jdk jaxws jaxp nashorn ];
|
|
sourceRoot = ".";
|
|
|
|
outputs = [ "out" "jre" ];
|
|
|
|
nativeBuildInputs = [ pkgconfig ];
|
|
buildInputs = [
|
|
cpio file which unzip zip perl bootjdk zlib cups freetype alsaLib
|
|
libjpeg giflib libX11 libICE libXext libXrender libXtst libXt libXtst
|
|
libXi libXinerama libXcursor lndir fontconfig
|
|
] ++ lib.optionals (!minimal && enableGnome2) [
|
|
gtk2 gnome_vfs GConf glib
|
|
];
|
|
|
|
prePatch = ''
|
|
ls | grep jdk | grep -v '^jdk8u' | awk -F- '{print $1}' | while read p; do
|
|
mv $p-* $(ls | grep '^jdk8u')/$p
|
|
done
|
|
cd $(ls | grep '^jdk8u')
|
|
'';
|
|
|
|
patches = [
|
|
./fix-java-home-jdk8.patch
|
|
./read-truststore-from-env-jdk8.patch
|
|
./currency-date-range-jdk8.patch
|
|
] ++ lib.optionals (!minimal && enableInfinality) [
|
|
./004_add-fontconfig.patch
|
|
./005_enable-infinality.patch
|
|
] ++ lib.optionals (!minimal && enableGnome2) [
|
|
./swing-use-gtk.patch
|
|
];
|
|
|
|
preConfigure = ''
|
|
chmod +x configure
|
|
substituteInPlace configure --replace /bin/bash "$shell"
|
|
substituteInPlace hotspot/make/linux/adlc_updater --replace /bin/sh "$shell"
|
|
'';
|
|
|
|
configureFlags = [
|
|
"--with-boot-jdk=${bootjdk.home}"
|
|
"--with-update-version=${update}"
|
|
"--with-build-number=${build}"
|
|
"--with-milestone=fcs"
|
|
"--enable-unlimited-crypto"
|
|
"--disable-debug-symbols"
|
|
"--disable-freetype-bundling"
|
|
"--with-zlib=system"
|
|
"--with-giflib=system"
|
|
"--with-stdc++lib=dynamic"
|
|
|
|
# glibc 2.24 deprecated readdir_r so we need this
|
|
# See https://www.mail-archive.com/openembedded-devel@lists.openembedded.org/msg49006.html
|
|
"--with-extra-cflags=\"-Wno-error=deprecated-declarations\""
|
|
] ++ lib.optional minimal "--disable-headful";
|
|
|
|
NIX_LDFLAGS= lib.optionals (!minimal) [
|
|
"-lfontconfig" "-lcups" "-lXinerama" "-lXrandr" "-lmagic"
|
|
] ++ lib.optionals (!minimal && enableGnome2) [
|
|
"-lgtk-x11-2.0" "-lgio-2.0" "-lgnomevfs-2" "-lgconf-2"
|
|
];
|
|
|
|
buildFlags = [ "all" ];
|
|
|
|
installPhase = ''
|
|
mkdir -p $out/lib/openjdk $out/share $jre/lib/openjdk
|
|
|
|
cp -av build/*/images/j2sdk-image/* $out/lib/openjdk
|
|
|
|
# Remove some broken manpages.
|
|
rm -rf $out/lib/openjdk/man/ja*
|
|
|
|
# Mirror some stuff in top-level.
|
|
mkdir $out/include $out/share/man
|
|
ln -s $out/lib/openjdk/include/* $out/include/
|
|
ln -s $out/lib/openjdk/man/* $out/share/man/
|
|
|
|
# jni.h expects jni_md.h to be in the header search path.
|
|
ln -s $out/include/linux/*_md.h $out/include/
|
|
|
|
# Remove crap from the installation.
|
|
rm -rf $out/lib/openjdk/demo $out/lib/openjdk/sample
|
|
${lib.optionalString minimal ''
|
|
rm $out/lib/openjdk/jre/lib/${architecture}/{libjsound,libjsoundalsa,libsplashscreen,libawt*,libfontmanager}.so
|
|
rm $out/lib/openjdk/jre/bin/policytool
|
|
rm $out/lib/openjdk/bin/{policytool,appletviewer}
|
|
''}
|
|
|
|
# Move the JRE to a separate output and setup fallback fonts
|
|
mv $out/lib/openjdk/jre $jre/lib/openjdk/
|
|
mkdir $out/lib/openjdk/jre
|
|
${lib.optionalString (!minimal) ''
|
|
mkdir -p $jre/lib/openjdk/jre/lib/fonts/fallback
|
|
lndir ${liberation_ttf}/share/fonts/truetype $jre/lib/openjdk/jre/lib/fonts/fallback
|
|
''}
|
|
lndir $jre/lib/openjdk/jre $out/lib/openjdk/jre
|
|
|
|
rm -rf $out/lib/openjdk/jre/bina
|
|
ln -s $out/lib/openjdk/bin $out/lib/openjdk/jre/bin
|
|
|
|
# Make sure cmm/*.pf are not symlinks:
|
|
# https://youtrack.jetbrains.com/issue/IDEA-147272
|
|
rm -rf $out/lib/openjdk/jre/lib/cmm
|
|
ln -s {$jre,$out}/lib/openjdk/jre/lib/cmm
|
|
|
|
# Set PaX markings
|
|
exes=$(file $out/lib/openjdk/bin/* $jre/lib/openjdk/jre/bin/* 2> /dev/null | grep -E 'ELF.*(executable|shared object)' | sed -e 's/: .*$//')
|
|
echo "to mark: *$exes*"
|
|
for file in $exes; do
|
|
echo "marking *$file*"
|
|
paxmark ${paxflags} "$file"
|
|
done
|
|
|
|
# Remove duplicate binaries.
|
|
for i in $(cd $out/lib/openjdk/bin && echo *); do
|
|
if [ "$i" = java ]; then continue; fi
|
|
if cmp -s $out/lib/openjdk/bin/$i $jre/lib/openjdk/jre/bin/$i; then
|
|
ln -sfn $jre/lib/openjdk/jre/bin/$i $out/lib/openjdk/bin/$i
|
|
fi
|
|
done
|
|
|
|
# Generate certificates.
|
|
pushd $jre/lib/openjdk/jre/lib/security
|
|
rm cacerts
|
|
perl ${./generate-cacerts.pl} $jre/lib/openjdk/jre/bin/keytool ${cacert}/etc/ssl/certs/ca-bundle.crt
|
|
popd
|
|
|
|
ln -s $out/lib/openjdk/bin $out/bin
|
|
ln -s $jre/lib/openjdk/jre/bin $jre/bin
|
|
ln -s $jre/lib/openjdk/jre $out/jre
|
|
'';
|
|
|
|
# FIXME: this is unnecessary once the multiple-outputs branch is merged.
|
|
preFixup = ''
|
|
prefix=$jre stripDirs "$stripDebugList" "''${stripDebugFlags:--S}"
|
|
patchELF $jre
|
|
propagatedNativeBuildInputs+=" $jre"
|
|
|
|
# Propagate the setJavaClassPath setup hook from the JRE so that
|
|
# any package that depends on the JRE has $CLASSPATH set up
|
|
# properly.
|
|
mkdir -p $jre/nix-support
|
|
echo -n "${setJavaClassPath}" > $jre/nix-support/propagated-native-build-inputs
|
|
|
|
# Set JAVA_HOME automatically.
|
|
mkdir -p $out/nix-support
|
|
cat <<EOF > $out/nix-support/setup-hook
|
|
if [ -z "\$JAVA_HOME" ]; then export JAVA_HOME=$out/lib/openjdk; fi
|
|
EOF
|
|
'';
|
|
|
|
postFixup = ''
|
|
# Build the set of output library directories to rpath against
|
|
LIBDIRS=""
|
|
for output in $outputs; do
|
|
LIBDIRS="$(find $(eval echo \$$output) -name \*.so\* -exec dirname {} \; | sort | uniq | tr '\n' ':'):$LIBDIRS"
|
|
done
|
|
|
|
# Add the local library paths to remove dependencies on the bootstrap
|
|
for output in $outputs; do
|
|
OUTPUTDIR="$(eval echo \$$output)"
|
|
BINLIBS="$(find $OUTPUTDIR/bin/ -type f; find $OUTPUTDIR -name \*.so\*)"
|
|
echo "$BINLIBS" | while read i; do
|
|
patchelf --set-rpath "$LIBDIRS:$(patchelf --print-rpath "$i")" "$i" || true
|
|
patchelf --shrink-rpath "$i" || true
|
|
done
|
|
done
|
|
|
|
# Test to make sure that we don't depend on the bootstrap
|
|
for output in $outputs; do
|
|
if grep -q -r '${bootjdk}' $(eval echo \$$output); then
|
|
echo "Extraneous references to ${bootjdk} detected"
|
|
exit 1
|
|
fi
|
|
done
|
|
'';
|
|
|
|
meta = with stdenv.lib; {
|
|
homepage = http://openjdk.java.net/;
|
|
license = licenses.gpl2;
|
|
description = "The open-source Java Development Kit";
|
|
maintainers = with maintainers; [ edwtjo ];
|
|
platforms = platforms.linux;
|
|
};
|
|
|
|
passthru = {
|
|
inherit architecture;
|
|
home = "${openjdk8}/lib/openjdk";
|
|
};
|
|
};
|
|
in openjdk8
|